6

Visual Studio 的 vcproj 文件包含影响构建的各种设置或属性。例如，我试图转换为 cmake 的项目使用的一些项目是

StringPooling="true"
RuntimeLibrary="2"
TreatWChar_tAsBuiltInType="true"
WarningLevel="3"
Detect64BitPortabilityProblems="false"

当然还有很多其他可以设置的。问题是如何在使用 cmake 生成项目时设置它们。除了事后编辑 vcproj 文件之外，有谁知道如何在使用 cmake 时设置这些类型的属性？我找不到任何解释如何通过 cmake 设置这些属性的内容。我唯一知道如何设置的是 cmake 专门用于（例如PreprocessorDefinitions或AdditionalIncludeDirectories）的跨平台内容。但我需要能够设置特定于 Visual Studio 的那些。

4

3 回答 3

8

对于您列出的标志，您需要将以下内容添加到您的 CMakeLists.txt：

if(MSVC)
  # StringPooling: true == /GF  false == /GF-
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /GF")

  # RuntimeLibrary
  # 0 (MultiThreaded) == /MT
  # 1 (MultiThreadedDebug) == /MTd
  # 2 (MultiThreadedDLL) == /MD
  # 3 (MultiThreadedDebugDLL) == /MDd
  set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MD")
  set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MDd")

  # TreatWChar_tAsBuiltInType: true == /Zc:wchar_t  false == /Zc:wchar_t-
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Zc:wchar_t")

  # WarningLevel: /W<level 0 to 4> or /Wall
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W3")

  # Detect64BitPortabilityProblems: /Wp64 - Deprecated since VC++ 2010 
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Wp64")
endif()

如果需要，您可以将它们组合在一个呼叫中：

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /GF /Zc:wchar_t /W3 /Wp64")

如果您只需要将标志添加到单个目标（例如MyTestExe），您可以执行以下操作：

set_target_properties(MyTestExe PROPERTIES COMPILE_FLAGS "/GF- /W2")

通过此特定于目标的方法设置的选项将覆盖通用CMAKE_CXX_FLAGS变量中的任何冲突选项。

有关这些命令的更多信息，请执行以下操作：

cmake --help-variable "CMAKE_<LANG>_FLAGS_DEBUG"
cmake --help-command set_target_properties
cmake --help-property COMPILE_FLAGS

此处列出了 Visual Studio 编译器选项。

于 2013-01-05T01:10:18.523 回答
1

这些属性中的每一个都对应于编译器的一个命令行选项 ( cl)。您在 CMakeList 中设置这些命令行选项（使用变量，如CMAKE_CXX_FLAGS，命令add_definitions()和属性COMPILE_FLAGS），CMake 会在生成它们时自动将它们转换为 .vc[x]proj 文件中的设置。那些它不理解的只是添加为“附加命令行选项”。

于 2013-01-04T08:58:54.780 回答
1

一般来说，你可以这样做：

set_target_properties(target_name
                      PROPERTIES VS_GLOBAL_CAExcludePath "....")

“VS_GLOBAL_ 可以设置为添加 Visual Studio 项目特定的全局变量。如果将 VS_GLOBAL_QtVersion 设置为找到的 Qt 版本 FindQt4.cmake，Qt 集成效果会更好。例如，“4.7.3””来源：https://cmake .org/cmake/help/v3.20/prop_tgt/VS_GLOBAL_variable.html

于 2021-04-14T01:21:50.553 回答