flash-media-server - SharedObject 发送方法

Question

在 FMS 中，我想使用共享对象在聊天应用程序中发送消息，因为它是实时的。我的问题是...您如何使用共享对象在实时聊天应用程序中向用户来回发送消息？这需要服务器端脚本、客户端还是两者兼而有之？

Answer 1

您只需要在服务器端为特定功能编写一些代码，例如安全功能（例如，如果不是所有用户都可以发送消息）。

在客户端，您需要：

• 连接到服务器；
• 从服务器获取共享对象。如果你请求时它不存在，它就会被创建；
• 为它添加一个监听器SyncEvent。

从那里，每次客户端使用该setProperty()方法添加、更新或删除 sharedObject 的属性时，所有连接的客户端都会收到一个SyncEvent.

package
{
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.IEventDispatcher;
    import flash.events.NetStatusEvent;
    import flash.events.SyncEvent;
    import flash.net.NetConnection;
    import flash.net.SharedObject;

    public class Chat extends EventDispatcher
    {
        public var messages:Array;
        private var connection:NetConnection;
        private var chat_so:SharedObject;

        public function Chat()
        {
            super();
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, onNetStatus);
            messages = [];
        }

        public function connect(uri:String):void
        {
            connection.connect(uri);
        }

        public function addMessage(value:String):void
        {
            chat_so.setProperty(messages.length.toString(), value);
        }

        private function setUpSharedObject():void
        {
            chat_so = SharedObject.getRemote("chat", connection.uri);
            chat_so.addEventListener(SyncEvent.SYNC, onSync);
            chat_so.client = this;
        }

        private function onNetStatus(event:NetStatusEvent):void
        {
            if (event.info.code == "NetConnection.Connect.Success")
            {
                setUpSharedObject();
            }
            else
            {
                trace(event.info.code + ": " + event.info.description);
            }
        }

        private function onSync(event:SyncEvent):void
        {
            for (var i:int = 0; i < event.changeList.length; i++)
            {
                var code:String = event.changeList[i].code;

                switch(code)
                {
                    case "change":
                    case "success":
                    {
                        messages.push();
                        dispatchEvent(new Event(Event.CHANGE));
                        break;
                    }
                    case "clear":
                    {
                        messages = [];
                        break;
                    }
                    case "delete":
                    default:
                    {
                        break;
                    }
                }
            }
        }
    }
}