0

我有一个这样的 XML

<filters>
      <ISP_WebItem FILTER="Type" FILTERNAME="Farvet" UNITCODE="" />
      <ISP_WebItem FILTER="Antal i pakke" FILTERNAME="1" UNITCODE="Farvepatro" />
      <ISP_WebItem FILTER="Farve" FILTERNAME="Rød" UNITCODE="" />
      <ISP_WebItem FILTER="Farve" FILTERNAME="Blå" UNITCODE="" />
      <ISP_WebItem FILTER="Farve" FILTERNAME="Gul" UNITCODE="" />
      <ISP_WebItem FILTER="Printer mærke" FILTERNAME="HP" UNITCODE="" />
</filters>

我想将此 XML 转换为类似这样的 HTML

Type          = Farvet
Antal i pakke = 1
farve         =Rød,Blå,Gul etc
Printer mærke =HP

您可以看到三个“FILTER”属性具有相同的值“Farve”。在我的 HTML 中，我希望它们以逗号分隔。作为执行此操作的第一步，我使用 Muenchian_grouping 对该 XML 的元素进行了分组，这样如果两个或多个 FILTER 属性相同，它们就会相邻。

然后我做了这样的事情

 <xsl:for-each select="$filt-grouped-formatted//ISP_WebItem[position() = 1 or @FILTER != preceding-sibling::*[1]/@FILTER ]">
              <xsl:variable name="current_filter" select="@FILTER" />
              <tr>
                <td width="200px">
                  <xsl:value-of select="$current_filter"/>:
                </td>
                <td>
                  <xsl:value-of select="@FILTERNAME"/>
                  <xsl:if test="@UNITCODE != ''">
                    <xsl:text> </xsl:text>
                    <xsl:value-of select="@UNITCODE"/>
                  </xsl:if>
                  <xsl:variable name="current_grouped_filter" select="$filt-grouped-formatted[@FILTER = $current_filter]" />

                  <xsl:if test="count($current_grouped_filter) &gt; 0">
                    <textarea>
                      <xsl:copy-of select="$current_grouped_filter"/>
                    </textarea>
                    <xsl:text>, </xsl:text>
                    <xsl:for-each select="$current_grouped_filter">
                      <xsl:value-of select="@FILTERNAME"/>
                      <xsl:if test="@UNITCODE != ''">
                        <xsl:text> </xsl:text>
                        <xsl:value-of select="@UNITCODE"/>
                      </xsl:if>
               <xsl:if test="count($current_grouped_filter) > position()">,</xsl:if>
                    </xsl:for-each>
                  </xsl:if>
                </td>
              </tr>
            </xsl:for-each>

唯一我无法实现的是分组元素没有出现。任何人都可以建议我在代码中进行编辑。

4

2 回答 2

1

实际上，使用现有的分组键一步完成此操作比先分组然后转换更容易。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:exslt="http://exslt.org/common"
                exclude-result-prefixes="exslt">
  <xsl:strip-space elements="*"/>
  <xsl:output method="text" />
  <xsl:key name="itemByFilter" match="ISP_WebItem" use="@FILTER" />

  <xsl:variable name="filt">
    <filters>
      <ISP_WebItem FILTER="Farve" FILTERNAME="Transparent" UNITCODE="" />
      <ISP_WebItem FILTER="Antal" FILTERNAME="10" UNITCODE="mapper" />
      <ISP_WebItem FILTER="Farve" FILTERNAME="blue" UNITCODE="" />
    </filters>
  </xsl:variable>

  <xsl:template match="/">
    <xsl:for-each select="exslt:node-set($filt)/filters">
      <xsl:apply-templates select="ISP_WebItem[
        generate-id() = generate-id(key('itemByFilter', @FILTER)[1])]" />
    </xsl:for-each>
  </xsl:template>

  <xsl:template match="ISP_WebItem">
    <xsl:value-of select="@FILTER" />
    <xsl:text> = </xsl:text>
    <xsl:for-each select="key('itemByFilter', @FILTER)">
      <xsl:if test="position() &gt; 1">,</xsl:if>
      <xsl:value-of select="@FILTERNAME" />
    </xsl:for-each>
    <xsl:text>&#10;</xsl:text>
  </xsl:template>
</xsl:stylesheet>
于 2013-01-03T09:10:47.263 回答
0

需要Muenchian_grouping进行分组，勾选这个

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:param name="versionParam" select="'1.0'"/>

    <xsl:key name="groups" match="ISP_WebItem" use="@FILTER" />
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/filters">
         <xsl:for-each select="//ISP_WebItem[generate-id() = generate-id(key('groups',@FILTER))]">
            <xsl:value-of select="@FILTER"/> = <xsl:value-of select="@FILTERNAME"/> 
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>
于 2013-01-03T07:58:49.070 回答