xml - 如何找到一个值并替换 XSL/XML 中的值？

Question

我有文档 .XML：

...
...
< memberValuePairs >
    < member path="Blabla">bla bla< /member >
    < member path="Zzzz">zz z z zzz< /member >
    < member path="word">my text< /member >
< /memberValuePairs >
...
...

我需要将标签“word”的值替换为“我的另一个文本”。我有来自命令的文件 XML：< xsl:copy >但我不知道如何查找和替换标记的值。

Answer 1

这种转变：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="member[@path='word']/text()[1]">
  <xsl:text>my another text</xsl:text>
 </xsl:template>
</xsl:stylesheet>

应用时（我假设是源 XML 文档）：

<memberValuePairs>
    <member path="Blabla">bla bla</member>
    <member path="Zzzz">zz z z zzz</member>
    <member path="word">my text</member>
</memberValuePairs>

产生想要的正确结果：

<memberValuePairs>
   <member path="Blabla">bla bla</member>
   <member path="Zzzz">zz z z zzz</member>
   <member path="word">my another text</member>
</memberValuePairs>