delphi - TSaveTextFileDialog 和 Vcl 样式

Question

我在 Delphi XE3 中使用TSaveTextFileDialog组件，但是当启用 Vcl 样式时，编码组合框是使用当前的 vcl 样式绘制的。

我该如何解决这个问题，我的意思是禁用组合框的 vcl 样式？

Answer 1

TSaveTextFileDialog组件的父类（TOpenTextFileDialog）添加了一组Vcl 组件来实现Encodings和EncodingIndex属性，您可以使用该属性禁用这些Vcl 控件上的Vcl 样式StyleElements。不幸的是，这些组件是私有的，因此您需要一点技巧才能获得访问权限并禁用 Vcl 样式。

在这里，您有两个选择。

使用类助手。

您可以引入一个辅助函数来获取包含对话框的 Vcl 控件的 Panel 组件。

type
 TOpenTextFileDialogHelper=class helper for TOpenTextFileDialog
  function GetPanel : TPanel;
 end;

function TOpenTextFileDialogHelper.GetPanel: TPanel;
begin
  Result:=Self.FPanel;
end;

然后您可以编写一个方法来禁用 Vcl 样式，如下所示：

procedure DisableVclStyles(const Control : TControl);
var
  i : Integer;
begin
  if Control=nil then
    Exit;
   Control.StyleElements:=[];

  if Control is TWinControl then
    for i := 0 to TWinControl(Control).ControlCount-1 do
      DisableVclStyles(TWinControl(Control).Controls[i]);
end;

最后以这种方式使用

  DisableVclStyles(SaveTextFileDialog1.GetPanel);
  SaveTextFileDialog1.Execute;

RTTI

另一种选择是使用 RTTI 访问私有 Vcl 组件。

var
  LRttiContext : TRttiContext;
  LRttiField :TRttiField;
begin
  LRttiContext:=TRttiContext.Create;
  for LRttiField in LRttiContext.GetType(SaveTextFileDialog1.ClassType).GetFields do
   if LRttiField.FieldType.IsInstance and LRttiField.FieldType.AsInstance.MetaclassType.ClassNameIs('TPanel') then
    DisableVclStyles(TPanel(LRttiField.GetValue(SaveTextFileDialog1).AsObject));

  SaveTextFileDialog1.Execute;
end;