0

我需要使用 gawk 的“FPAT”或等效函数“patsplit”。但是在我们的 CentOs 服务器上，gawk 的安装版本似乎是 3.1.5。

我尝试使用以下命令更新 gawk：

yum update gawk;

服务器显示：“没有标记为更新的包”

我还尝试使用以下方法重新安装 gawk：

 yum install gawk;

服务器输出：“包 gawk-3.1.5-15.el5.x86_64 已安装且最新版本”

我需要 gawk 4.0 或更高版本才能使用那些 FPAT 或 patsplit。为什么我需要使用它们？好吧，我正在尝试处理一个 CSV 文件，似乎 CSV 文件有可选的引号和嵌入的逗号。

例子：

从这样的 csv 行：

this,is,a,"csv,with,embedded coma"

我需要像这样拆分字段：

this

is

a

"csv,with,embedded comma"

这是 gawk 代码：

awk '{patsplit("this,is,a,\"csv,with,embedded comma\"",a,"([^,]*)|(\"([^\"]|\"\")+\"[^,]*)",seps); for(i=0;i<length(a);i++) print a[i];}';

有人可以帮我吗？

4

5 回答 5

2

尝试在您的管道中使用 csvquote 以使数据易于 awk 解释。这是我编写的脚本，它用非打印字符替换引用字段中的逗号，然后恢复它们。

因此，如果您的 awk 命令最初看起来像这样：

awk -F, '{print $3 "," $5}' inputfile.csv

...可以使用 csv 引用的分隔符，如下所示：

csvquote inputfile.csv | awk -F, '{print $3 "," $5}' | csvquote -u

有关代码和更多文档，请参阅https://github.com/dbro/csvquote

于 2013-05-04T23:31:39.900 回答
1

我认为我们可以使用 match() 来获取字段。

以下是代码：

awk '{ $0=$0","                                   
while($0) {
  match($0,/ *"[^"]*" *,|[^,]*,/) 
  field=substr($0,RSTART,RLENGTH)            
  gsub(/,$/,"",field)   
  print field
  $0=substr($0,RLENGTH+1)              
}}' file

使用您的输入示例进行测试：

kent$  echo 'this,is,a,"csv,with,embedded coma"'|awk '{
$0=$0","                                   
while($0) {
  match($0,/ *"[^"]*" *,|[^,]*,/) 
  field=substr($0,RSTART,RLENGTH)            
  gsub(/,$/,"",field)   
  print field
  $0=substr($0,RLENGTH+1)              
}}'
this
is
a
"csv,with,embedded coma"
于 2013-01-02T14:13:49.230 回答
1

最简单的做法是在进行实际处理之前将引号之外的逗号转换为其他内容。例如：

$ cat file
this,is,a,"csv,with,embedded coma",and,here,"is,another",one
and,here,"is,another,line"
$
$ awk 'BEGIN{FS=OFS="\""}{for (i=1;i<=NF;i+=2) gsub(/,/,";",$i)}1' file
this;is;a;"csv,with,embedded coma";and;here;"is,another";one
and;here;"is,another,line"

如果您不喜欢“;”作为字段分隔符，请选择其他内容，例如控制字符，或者这里有一个使用换行符作为 FS 和空行作为 RS 的示例：

$ awk 'BEGIN{FS=OFS="\""; ORS="\n\n"}{for (i=1;i<=NF;i+=2) gsub(/,/,"\n",$i)}1' file
this
is
a
"csv,with,embedded coma"
and
here
"is,another"
one

and
here
"is,another,line"

$ awk 'BEGIN{FS=OFS="\""; ORS="\n\n"}{for (i=1;i<=NF;i+=2) gsub(/,/,"\n",$i)}1' file |
awk -F'\n' -v RS= '{for (i=1;i<=NF;i++) print NR,i,"<" $i ">"}'
1 1 <this>
1 2 <is>
1 3 <a>
1 4 <"csv,with,embedded coma">
1 5 <and>
1 6 <here>
1 7 <"is,another">
1 8 <one>
2 1 <and>
2 2 <here>
2 3 <"is,another,line">

仅当您嵌入了换行符或嵌入了转义双引号时，它才会变得棘手。

于 2013-01-02T20:44:36.303 回答
0

这是一个纯粹的 GAWK 解决方案：

{ # Split on double quotes to handle lines like "this, this, or this".
    printf("LINE:    '%s'\nFIELDS:", $0)
    n = split($0,q,/"/)
    f = 0
}

n == 1 { # If n is 1, there are no double quotes on the line.
    n = split($0,c,/,/)
    for (i = 1; i <= n; i++) {
        printf("  %d='%s'", i, c[i])
    }
    printf("\n")
    next
}

{ # There are "strings"; the EVEN entries in q are the quoted strings.
    for (i = 1; i <= n; i++) {
        if (0 == and(i,1)) { # i is EVEN: This is a double-quoted string.
            printf("  %d='\"%s\"'", ++f, q[i])
            continue
        }
        if (0 == length(q[i])) { # First/last field is a quoted string.
            continue
        }
        if (q[i] == ",") {
            # First/last field empty, or comma between two quoted strings.
            if (i == 1 || i == n) { # First/last field empty
                printf("  %d=''", ++f)
            }
            continue
        }
        # Remove commas before/after a quoted string then split on commas.
        sub(/^,/,"",q[i])
        sub(/,$/,"",q[i])
        m = split(q[i],cq,/,/)
        for (j = 1; j <= m; j++) {
            printf("  %d='%s'", ++f, cq[j])
        }
    }
    printf("\n")
}

使用此输入：

This is one,23,$9.32,Another string.
Line 2,234,$88.34,Blah blah
"This is another",763,$0.00,"trouble, or not?"
"This is, perhaps, trouble too...",763,$0.00,"trouble, or not?"
2,"This is, perhaps, trouble too...",763,"trouble, or not?"
3,,"number, number","well?"
,,,
"1,one","2,two","3,three","4,four"
",commas,","no commas",",,,,,",
,"Fields 1 and 4 are empty","But 2 and 3 are not",

产生此输出：

LINE:    'This is one,23,$9.32,Another string.'
FIELDS:  1='This is one'  2='23'  3='$9.32'  4='Another string.'
LINE:    'Line 2,234,$88.34,Blah blah'
FIELDS:  1='Line 2'  2='234'  3='$88.34'  4='Blah blah'
LINE:    '"This is another",763,$0.00,"trouble, or not?"'
FIELDS:  1='"This is another"'  2='763'  3='$0.00'  4='"trouble, or not?"'
LINE:    '"This is, perhaps, trouble too...",763,$0.00,"trouble, or not?"'
FIELDS:  1='"This is, perhaps, trouble too..."'  2='763'  3='$0.00'  4='"trouble, or not?"'
LINE:    '2,"This is, perhaps, trouble too...",763,"trouble, or not?"'
FIELDS:  1='2'  2='"This is, perhaps, trouble too..."'  3='763'  4='"trouble, or not?"'
LINE:    '3,,"number, number","well?"'
FIELDS:  1='3'  2=''  3='"number, number"'  4='"well?"'
LINE:    ',,,'
FIELDS:  1=''  2=''  3=''  4=''
LINE:    '"1,one","2,two","3,three","4,four"'
FIELDS:  1='"1,one"'  2='"2,two"'  3='"3,three"'  4='"4,four"'
LINE:    '",commas,","no commas",",,,,,",'
FIELDS:  1='",commas,"'  2='"no commas"'  3='",,,,,"'  4=''
LINE:    ',"Fields 1 and 4 are empty","But 2 and 3 are not",'
FIELDS:  1=''  2='"Fields 1 and 4 are empty"'  3='"But 2 and 3 are not"'  4=''
于 2014-10-20T13:33:18.347 回答
0

如果您可以访问 yum，现在应该称为 dnf，请参阅

https://en.wikipedia.org/wiki/DNF_（软件）

那么你可以作为普通用户运行

git clone https://git.savannah.gnu.org/git/gawk.git
cd gawk
./configure
make
sudo make install

那么你的 tmp.txt 输入文件的问题

this,is,a,"csv,with,embedded coma"

很容易转换为

gawk '{patsplit("this,is,a,\"csv,with,embedded comma\"",a,"([^,]*)|(\"([^\"]|\"\")+\"[^,]*)",seps); for(i=0;i<length(a);i++) print a[i];}' tmp.txt

您可能在编译 gawk 时遇到问题，如果它们弹出，您应该解决这些问题。

于 2019-11-12T19:35:00.733 回答