2

我需要能够输出由换行符分隔的 XML 文档的文本。换句话说，XML：

<programlisting>
public static void main(String[] args){
    System.out.println("Be happy!");  
    System.out.println("And now we add annotations.");  
}
</programlisting>

需要表示为：

<para>public static void main(String[] args){</para>
<para>    System.out.println("Be happy!"); </para>
<para>    System.out.println("And now we add annotations.");  </para>
<para>}</para>

我认为我应该能够使用 substring-before(., '\n') 但由于某种原因它无法识别换行符。

我还尝试将每一行输出为一个 CDATA 部分，以便我可以单独提取它们，但遇到了这样一个事实，即它们都被混合到一个文本节点中。

我只是在这里使用常规 Java 进行转换。关于如何做到这一点的任何想法？

谢谢...

4

2 回答 2

2

正如这个答案中所解释的，XML 中的所有换行符都被视为实体&#10;。这意味着，要在换行符处拆分字符串，您必须在此实体处拆分。

因此，纯 XSLT 1.0（无扩展）中的解决方案可能如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
  <xsl:output indent="yes"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="programlisting/text()">
    <xsl:param name="text" select="."/>
    <para>
      <!-- Because we would rely on $text containing a line break when using 
           substring-before($text,'&#10;') and the last line might not have a
           trailing line break, we append one before doing substring-before().  -->
      <xsl:value-of select="substring-before(concat($text,'&#10;'),'&#10;')"/>
    </para>
    <xsl:if test="contains($text,'&#10;')">
      <xsl:apply-templates select=".">
        <xsl:with-param name="text" select="substring-after($text,'&#10;')"/>
      </xsl:apply-templates>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

<para>对于给定的 XML 源，这会在第一个和最后一个换行符处输出一些空元素。也可以检查空行（如 Dimitre 所做的那样）。然而，这也会删除代码列表中间某处的空行。如果在开头和结尾删除空行很重要，而在中间保留空行，则需要一些更聪明的方法。

这只是表明使用普通 XSLT 1.0 完成这项任务并不困难。

于 2012-12-30T20:13:09.637 回答
1

一、XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()">
  <xsl:for-each select="tokenize(., '\n\r?')[.]">
   <para><xsl:sequence select="."></xsl:sequence></para>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<programlisting>
public static void main(String[] args){
    System.out.println("Be happy!");
    System.out.println("And now we add annotations.");
}
</programlisting>

产生了想要的正确结果：

<programlisting>
   <para>public static void main(String[] args){</para>
   <para>    System.out.println("Be happy!");</para>
   <para>    System.out.println("And now we add annotations.");</para>
   <para>}</para>
</programlisting>

二、XSLT 1.0 解决方案，使用FXSLstr-split-to-words模板：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
  <xsl:import href="strSplit-to-Words.xsl"/>
  <xsl:output indent="yes" omit-xml-declaration="yes"/>

   <xsl:strip-space elements="*"/>
   <xsl:output indent="yes" omit-xml-declaration="yes"/>

   <xsl:param name="pDelims" select="'&#xA;&#xD;'"/>

    <xsl:template match="/">
      <xsl:variable name="vwordNodes">
        <xsl:call-template name="str-split-to-words">
          <xsl:with-param name="pStr" select="/"/>
          <xsl:with-param name="pDelimiters"
                          select="$pDelims"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:apply-templates select=
      "ext:node-set($vwordNodes)/*[normalize-space()]"/>
    </xsl:template>

    <xsl:template match="word">
      <para><xsl:value-of select="."/></para>
    </xsl:template>
</xsl:stylesheet>

当此转换应用于同一个 XML 文档（如上）时，会产生相同的正确结果：

<para>public static void main(String[] args){</para>
<para>    System.out.println("Be happy!");</para>
<para>    System.out.println("And now we add annotations.");</para>
<para>}</para>
于 2012-12-30T18:52:48.930 回答