z3 - 有没有办法通过 API 查询或访问 Z3 表达式的结构

Question

我正在从 F# 访问托管 API。我可以使用 ctx.MkFalse、MkImplies、MkMul 等构造 Z3 表达式，但是如何遍历 Z3 表达式以发现其结构？是否有类似 e.Op 或 e.IsFalse、e.IsImplies 等的东西？

Answer 1

您应该查看Expr.cs的文档。

这是一个遍历表达式的简单 F# 示例：

let traverse (expr: Expr) =
    printfn "num args: %O" expr.NumArgs
    printfn "children: %A" expr.Args
    printfn "1st child: %O" expr.Args.[0]
    printfn "2nd child: %O" expr.Args.[1]
    printfn "operator: %O" expr.FuncDecl
    printfn "op name: %O" expr.FuncDecl.Name

Expr该类还公开了所有术语种类测试，包括 IsTrue、IsAnd、isImplies 等，这些测试是发现表达式结构所必需的。在 F# 中，您应该定义一组活动模式：

let (|True|_|) (expr: Expr) = if expr.IsTrue then Some() else None
let (|False|_|) (expr: Expr) = if expr.IsFalse then Some() else None

let (|And|_|) (expr: Expr) = if expr.IsAnd then Some expr.Args else None
let (|Or|_|) (expr: Expr) = if expr.IsOr then Some expr.Args else None
let (|Not|_|) (expr: Expr) = if expr.IsNot && expr.NumArgs = 1u 
                             then Some(expr.Args.[0]) else None

let (|Iff|_|) (expr: Expr) = if expr.IsIff && expr.NumArgs = 2u 
                             then Some(expr.Args.[0], expr.Args.[1]) else None
let (|Implies|_|) (expr: Expr) = if expr.IsImplies && expr.NumArgs = 2u 
                                 then Some(expr.Args.[0], expr.Args.[1]) else None

这样您就可以通过模式匹配轻松查询表达式的结构，即使是递归方式：

match e with
| True -> (* boolean literal *)
| False -> (* boolean literal *)
| And es -> (* query es; possibly by pattern matching *)
| Or es -> (* query es; possibly by pattern matching *)
| Not e' -> (* query e; possibly by pattern matching *)
| Iff(e1, e2) -> (* query e1, e2; possibly by pattern matching *)
| Implies(e1, e2) -> (* query e1, e2; possibly by pattern matching *)
| _ -> (* Not a boolean expression; do something else *)