2
4

3 回答 3

2

href要删除属性中包含不需要的字符串的锚点，请展开matchXPath 表达式：

<xsl:template match="a[not(contains(@href,'Foo'))]">...

Foo可能是spammycrap.com或其他。

此外，您可以为空锚和非空锚指定不同的模板。因此，对于非空锚点，您将使用：

<xsl:template match="a[not(contains(@href,'Foo')) and not(count(node()) = 0)]">...

其次是非空锚的模板。然后对于空锚：

<xsl:template match="a[not(contains(@href,'Foo')) and not(node())]">...

其次是空锚的模板。

总的来说，这变成：

<xsl:template match="a[not(contains(@href,'Foo')) and not(count(node()) = 0)]">[url="<xsl:value-of select="@href"/>"]<xsl:apply-templates/>[/url]</xsl:template>

<xsl:template match="a[not(contains(@href,'Foo')) and not(node())]">[url]<xsl:value-of select="@href"/>[/url]</xsl:template>
于 2012-12-29T14:57:09.000 回答
1

您可以使用空模板忽略特定元素，例如

<xsl:template match="a[contains(@href, 'badurl')]" />

要查找非空a元素，您可以使用

<xsl:template match="a[*|text()[normalize-space(.)]]">
  <xsl:text>[url="</xsl:text>
  <xsl:value-of select="@href"/>
  <xsl:text>"]</xsl:text>
  <xsl:apply-templates/>
  <xsl:text>[/url]</xsl:text>
</xsl:template>

它匹配任何具有不完全空白的子元素或文本节点的锚点。与此模式不匹配的锚点将被通用match="a"模板拾取

<xsl:template match="a">[url]<xsl:value-of select="@href" />[/url]</xsl:template>
于 2012-12-29T15:15:05.060 回答
0

这种转变：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="a[starts-with(@href, 'http://spammy')]"/>

 <xsl:template match="a[not(*|text()[normalize-space(.)])]">
  <xsl:text>[url]</xsl:text>
    <xsl:value-of select="@href"/>
  <xsl:text>[/url]&#xA;</xsl:text>
 </xsl:template>

 <xsl:template match="a">
  <xsl:text>[url="</xsl:text>
  <xsl:value-of select="@href"/>"]<xsl:text/>
  <xsl:value-of select="."/>
  <xsl:text>[/url]&#xA;</xsl:text>
 </xsl:template>
</xsl:stylesheet>

应用于此 XML 文档时：

<html>
    <a href="http://spammycrap.tld">Foo</a>
    <a href="http://empty.tld"></a>
    <a href="http://empty2.tld">    </a>
    <a href="http://okay.tld">Baz</a>
</html>

产生想要的正确结果：

[url]http://empty.tld[/url]
[url]http://empty2.tld[/url]
[url="http://okay.tld"]Baz[/url]
于 2012-12-29T17:45:35.713 回答