0

我有一个非常简单的代码片段；

loadingMc.visible = true;
trace("ok");
// send photo to server
loadingMc.visible = false;

发送照片需要 3-5 秒，但影片剪辑仅在过程的最后一秒可见。我可以在流程开始时在输出中看到“ok”消息。所以我认为问题不是重绘影片剪辑。是否有任何选项可以在流程开始之前强制重绘？

更新：发送到服务器部分；

upload.addEventListener(MouseEvent.CLICK, function(evt:MouseEvent):void{
    loadingText.visible = true;
    trace("ok");
    var bmd:BitmapData = new BitmapData(1024,768,true,0);
    bmd.draw(imageArea);
    savePicToServer(bmd);
});

function savePicToServer(bmd:BitmapData):void
{   
    var jpgEncoder:JPGEncoder = new JPGEncoder(85);
    var jpgStream:ByteArray = jpgEncoder.encode(bmd);

    var loader:URLLoader = new URLLoader();
    configureListeners(loader);
    var header:URLRequestHeader = new URLRequestHeader("Content-type", "application/octet-stream");
    var request:URLRequest = new URLRequest("http://localhost/test/upload.php?key=prvkey");
    request.requestHeaders.push(header);
    request.method = URLRequestMethod.POST;
    request.data = jpgStream;
    loader.load(request);
}

在 COMPLETE 事件中；

loadingText.visible = false;
4

1 回答 1

1

编辑

仅仅通过阅读您的代码，我不明白为什么这不应该工作 - 但 FP 有时会做一些奇怪的事情。

在类似的情况下，我曾经setTimeout()强制播放器延迟后续动作并允许屏幕刷新：

upload.addEventListener(MouseEvent.CLICK, function(evt:MouseEvent):void{
    loadingText.visible = true;
    trace("ok");
    setTimeout( doSave, 10 );
});

private function doSave() : void {
    var bmd:BitmapData = new BitmapData(1024,768,true,0);
    bmd.draw(imageArea);
    savePicToServer(bmd);
}

如果这仍然不起作用，也许更长的超时时间可以解决问题 - 但 10 毫秒通常应该足以刷新屏幕。

编辑

另一种方法是添加和删除一个ENTER_FRAME侦听器以确保框架确实被刷新：

upload.addEventListener(MouseEvent.CLICK, function(evt:MouseEvent):void{
    loadingText.visible = true;
    trace("ok");
    addEventListener( Event.ENTER_FRAME, onNextFrame );
});

private function onNextFrame( ev:Event ) : void {
    removeEventListener( Event.ENTER_FRAME, onNextFrame );
    doSave();
}

private function doSave() : void {
    var bmd:BitmapData = new BitmapData(1024,768,true,0);
    bmd.draw(imageArea);
    savePicToServer(bmd);
}
于 2012-12-29T01:21:23.717 回答