1

我有如下 xml（使用 xslt 1.0）：

<?xml version="1.0" encoding="utf-8"?>
    <receives>
    <receive>
    <Year>2013</Year>
    <money>120</money>
    </receive>
    <receive>
    <Year>2013</Year>
    <money>150</money>
    </receive>
    <receive>
    <Year>2014</Year>
    <money>130</money>
    </receive>
    <receive>
    <Year>2011</Year>
    <money>120</money>
        </receive>
</receives>

我想按年份对钱进行分组，如果年份不在列表中（如上 xml，没有 2011），我需要将 2012 放入结果中，totalamount=0 如下：

<year>2011</year>
<totalamount>120</totalamount>
<year>2012</year>
<totalamount>0</totalamount>
<year>2013</year>
<totalamount>270</totalamount>
<year>2014</year>
<totalamount>130</totalamount>

目前，我已经完成了 xslt，如下所示： 

<xsl:key name="receive-key" match="receive" use="Year" />

<xsl:template match="/receives">
    <xsl:for-each
        select="receive[generate-id() = generate-id(key('receive-key', Year))]">
            <xsl:sort select="../receive[Year = current()/Year]/Year"></xsl:sort>
            <year>
                <xsl:value-of select="../receive[Year = current()/Year]/Year" />
            </year>
            <totalamount>
                <xsl:value-of select="sum(../receive[Year = current()/Year]/money)" />
            </totalamount>
    </xsl:for-each>
</xsl:template>

这只能按现有年份对钱进行分组：

<year>2011</year>
<totalamount>120</totalamount> 
<year>2013</year>
<totalamount>270</totalamount>
<year>2014</year>
<totalamount>130</totalamount>

关于如何插入的任何想法

<year>2012</year>
<totalamount>0</totalamount>

结果？

非常感谢！

4

1 回答 1

2

一种方法是使用命名模板，该模板以年份为参数调用。如果键中不存在今年，则输出一个空值，并为下一年调用。

<xsl:template name="Year">
   <xsl:param name="Year"/>
   <xsl:if test="not(key('receive-key', $Year))">
      <year>
         <xsl:value-of select="$Year"/>
      </year>
      <totalamount>0</totalamount>
      <xsl:call-template name="Year">
         <xsl:with-param name="Year" select="$Year + 1"/>
      </xsl:call-template>
   </xsl:if>
</xsl:template>

因此，一旦在 key 中找到年份，它将停止输出丢失的年份。

要注意的另一件事是 XSLT 中的表达式之一

<xsl:value-of select="../receive[Year = current()/Year]/Year" />

这实际上可以简化为！

<xsl:value-of select="Year"/>

同样，您可以更改总和以使用xsl:key来提高效率

<xsl:value-of select="sum(key('receive-key', Year)/money)"/>

这是完整的 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:key name="receive-key" match="receive" use="Year"/>

   <xsl:template match="/receives">
      <xsl:for-each select="receive[generate-id() = generate-id(key('receive-key', Year))]">
         <xsl:sort select="Year"/>
         <year>
            <xsl:value-of select="Year"/>
         </year>
         <totalamount>
            <xsl:value-of select="sum(key('receive-key', Year)/money)"/>
         </totalamount>
         <xsl:if test="position() != last()">
            <xsl:call-template name="Year">
               <xsl:with-param name="Year" select="number(Year) + 1"/>
            </xsl:call-template>
         </xsl:if>
      </xsl:for-each>
   </xsl:template>

   <xsl:template name="Year">
      <xsl:param name="Year"/>
      <xsl:if test="not(key('receive-key', $Year))">
         <year>
            <xsl:value-of select="$Year"/>
         </year>
         <totalamount>0</totalamount>
         <xsl:call-template name="Year">
            <xsl:with-param name="Year" select="$Year + 1"/>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>
</xsl:stylesheet>

当应用于您的 XML 时，将输出以下内容

<year>2011</year>
<totalamount>120</totalamount>
<year>2012</year>
<totalamount>0</totalamount>
<year>2013</year>
<totalamount>270</totalamount>
<year>2014</year>
<totalamount>130</totalamount>
于 2012-12-28T09:19:25.973 回答