5

我正在用 Indy 10 编写一个简单的客户端/服务器聊天程序。我的服务器（idtcpserver）向客户端发送命令，客户端回答，但是当连接多个客户端并且服务器发送命令时，所有客户端都连接向服务器发送数据。

如何将命令发送到指定的客户端而不是全部？

4

2 回答 2

6

可以将命令发送到所有连接的客户端的唯一方法是，如果您的代码循环遍历所有向每个客户端发送命令的客户端。因此，只需删除该循环，或者至少将其更改为仅发送给您感兴趣的特定客户端。

向客户端发送命令以避免由于重叠命令而破坏与该客户端的通信的最佳位置是来自该客户端自己的OnExecute事件，例如：

procedure TForm1.IdTCPServer1Execute(AContext: TIdContext);
begin
  ...
  if (has a command to send) then
  begin
    AContext.Connection.IOHandler.WriteLn(command here);
    ...
  end;
  ...
end;

如果您需要从其他线程向客户端发送命令，那么最好为该客户端提供自己的出站命令队列，然后让该客户端的OnExecute事件在安全的情况下发送队列。其他线程可以在需要时将命令推送到队列中。

type
  TMyContext = class(TIdServerContext)
  public
    ClientName: String;
    Queue: TIdThreadSafeStringList;
    constructor Create(AConnection: TIdTCPConnection; AYarn: TIdYarn; AList: TThreadList = nil); override;
    destructor Destroy; override; 
  end;

constructor TMyContext.Create(AConnection: TIdTCPConnection; AYarn: TIdYarn; AList: TThreadList = nil);
begin
  inherited Create(AConnection, AYarn, AList);
  Queue := TIdThreadSafeStringList.Create;
end;

destructor TMyContext.Destroy;
begin
  Queue.Free;
  inherited Destroy;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  IdTCPServer1.ContextClass := TMyContext;
end;

procedure TForm1.SendCommandToClient(const ClientName, Command: String);
var
  List: TList;
  I: Ineger;
  Ctx: TMyContext;
begin
  List := IdTCPServer1.Contexts.LockList;
  try
    for I := 0 to List.Count-1 do
    begin
      Ctx := TMyContext(List[I]);
      if Ctx.ClientName = ClientName then
      begin
        Ctx.Queue.Add(Command);
        Break;
      end;
    end;
  finally
    IdTCPServer1.Context.UnlockList;
  end;
end;

procedure TForm1.IdTCPServer1Connect(AContext: TIdContext);
var
  List: TList;
  I: Ineger;
  Ctx, Ctx2: TMyContext;
  ClientName: String;
begin
  Ctx := TMyContext(AContext);
  ClientName := AContext.Connection.IOHandler.ReadLn;
  List := IdTCPServer1.Contexts.LockList;
  try
    for I := 0 to List.Count-1 do
    begin
      Ctx2 := TMyContext(List[I]);
      if (Ctx2 <> Ctx) and (Ctx.ClientName = ClientName) then
      begin
        AContext.Connection.IOHandler.WriteLn('That Name is already logged in');
        AContext.Connection.Disconnect;
        Exit;
      end;
    end;
    Ctx.ClientName = ClientName;
  finally
    IdTCPServer1.Context.UnlockList;
  end;
  AContext.Connection.IOHandler.WriteLn('Welcome ' + ClientName);
end;

procedure TForm1.IdTCPServer1Disconnect(AContext: TIdContext);
var
  Ctx: TMyContext;
begin
  Ctx := TMyContext(AContext);
  Ctx.ClientName = '';
  Ctx.Queue.Clear;
end;

procedure TForm1.IdTCPServer1Execute(AContext: TIdContext);
var
  Ctx: TMyContext;
  Queue: TStringList;
begin
  Ctx := TMyContext(AContext);
  ...
  Queue := Ctx.Queue.Lock;
  try
    while Queue.Count > 0 do
    begin
      AContext.Connection.IOHandler.WriteLn(Queue[0]);
      Queue.Delete(0);
      ...
    end;
    ...
  finally
    Ctx.Queue.Unlock;
  end;
end;
于 2012-12-27T21:28:36.037 回答
6

通常在客户端/服务器设置中，客户端发起联系，服务器响应。使用 IdTCPServer 公开的事件，这始终是特定于上下文（连接）的，因此您不必做任何特别的事情。

要启动从服务器到客户端的联系，您必须跟踪连接的客户端并使用所需客户端的连接向其发送消息。为此，您需要一个列表来保存已连接的客户端，并且需要为 OnConnect 和 OnDisconnect 事件实现处理程序。

type
  TForm1 = class(TForm)
  private
    FClients: TThreadList;

procedure TForm1.HandleClientConnect(aThread: TIDContext);
begin
  FClients.Add(aThread);
end;

procedure TForm1.HandleClientDisconnect(aThread: TIDContext);
begin
  FClients.Remove(aThread);
end;

当您想向特定客户端发送数据时，您可以使用通过 TCP 连接发送数据的常规方法来实现。但首先您需要在 FClients 列表中找到您需要的特定客户端。

如何识别特定客户完全取决于您。当客户端首次连接并识别自己时，这将完全取决于您在客户端和服务器之间交换的信息。话虽如此，无论该信息如何，该机制都是相同的。

TIDContext 是 Indy 用来保存连接详细信息的 TIdServerContext 类的祖先。您可以从 TIdServerContext 下降到一个可以存储您自己的连接详细信息的地方。

type
  TMyContext = class(TIdServerContext)
  private
    // MyInterestingUserDetails...

ContextClass使用其属性告诉 Indy 使用您自己的 TIdServerContext 后代。您当然需要在激活服务器之前执行此操作，例如在 OnCreate 中。

procedure TForm1.HandleTcpServerCreate(Sender: TObject);
begin
  FIdTcpServer1.ContectClass = TMyContext;
end;

然后你可以在任何有 TIdContext 参数的地方使用你自己的类，方法是将它转换为你自己的类：

procedure TForm1.HandleClientConnect(aThread: TIDContext);
var 
  MyContext: TMyContext;
begin
  MyContext := aThread as TMyContext;
end;

然后，查找特定客户端的连接就变成了遍历 FClients 列表并检查它包含的 TMyContext 是否是您想要的问题：

function TForm1.FindContextFor(aClientDetails: string): TMyContext;
var
  LockedList: TList;
  idx: integer;
begin
  Result := nil;
  LockedList := FClients.LockList;
  try
    for idx := 0 to LockedList.Count - 1 do
    begin
      MyContext := LockedList.Items(idx) as TMyContext;
      if SameText(MyContext.ClientDetails, aClientDetails) then
      begin
        Result := MyContext;
        Break;
      end;
    end;
  finally
    FClients.UnlockList;
  end;

编辑：正如 Remy 在评论中指出的那样：为了线程安全，您应该在写入客户端时保持列表锁定（这对吞吐量和性能来说不是一件好事），或者用 Remy 的话来说：

“更好的选择是给 TMyContext 自己的 TIdThreadSafeStringList 用于出站数据，然后让客户端的 OnExecute 事件在安全的情况下将该列表写入客户端。其他客户端的 OnExecute 事件可以在需要时将数据推送到该列表中。”

于 2012-12-27T12:27:44.563 回答