4

我正在尝试将此 PHP 验证代码转换为 ColdFusion。但是，我无法让我的 CF 版本正确验证 VIN。我希望有人可以阐明我所缺少的东西。

<cfscript>
    function isVIN(v) {
        var i = "";
        var d = "";
        var checkdigit = "";
        var sum = 0;
        var weights = [8, 7, 6, 5, 4, 3, 2, 10, 0, 9, 8, 7, 6, 5, 4, 3, 2];
        var transliterations = {
            a = 1,
            b = 2,
            c = 3,
            d = 4,
            e = 5,
            f = 6,
            g = 7,
            h = 8,
            j = 1,
            k = 2,
            l = 3,
            m = 4,
            n = 5,
            p = 7,
            r = 9,
            s = 2,
            t = 3,
            u = 4,
            v = 5,
            w = 6,
            x = 7,
            y = 8,
            z = 9
        };

        if (! REFindNoCase("^([\w]{3})[A-Z]{2}\d{2}([A-Z]{1}|\d{1})([\d{1}|X{1})([A-Z]+\d+|\d+[A-Z]+)\d{5}$", ARGUMENTS.v)) {
            return false;
        }

        if (Len(ARGUMENTS.v) != 17) {
            return false;
        }

        for (i = 1; i <= Len(ARGUMENTS.v); i++) {
            d = Mid(ARGUMENTS.v, i, 1);

            if (! isNumeric(d)) {
                sum += transliterations[d] * weights[i];
            } else {
                sum += d * weights[i];
            }
        }

        checkdigit = sum % 11;

        if (checkdigit == 10) {
            checkdigit = "x";
        }

        if (checkdigit == Mid(ARGUMENTS.v,8,1)) {
            return true;
        }

        return false;
    }
</cfscript>

（CFLib.org 上有一个 VIN 验证功能，但它也不起作用）。

4

2 回答 2

8

您的功能有两个问题。

首先，正则表达式不正确。这是一个简化的工作版本：

^[A-Z\d]{3}[A-Z]{2}\d{2}[A-Z\d][\dX](?:[A-Z]+\d+|\d+[A-Z]+)\d{5}$

注意：根据亚当的回答，有一个比这更简单的模式。


其次，在您的校验位比较中，Mid 是一个出局 - 似乎 8 应该是 9。

（推测这是一个语言转换问题，因为 PHP 是 0 索引，而 CFML 是 1 索引。）


在这两个固定的情况下，修改后的函数为 VIN 返回 true WAUBA24B3XN104537（这是我在快速搜索中可以找到的唯一示例 VIN）。

于 2012-12-20T19:16:12.977 回答
3

实际上正则表达式仍然有点错误。我认为@PeterBoughton 修复了语法，但它实际上不适用于手头的任务。

这是修改后的代码部分，带有适当的注释：

var vinRegex = "(?x)    ## allow comments
    ^                   ## from the start of the string
                        ## see http://en.wikipedia.org/wiki/Vehicle_Identification_Number for VIN spec
    [A-Z\d]{3}          ## World Manufacturer Identifier (WMI)
    [A-Z\d]{5}          ## Vehicle decription section (VDS)
    [\dX]               ## Check digit
    [A-Z\d]             ## Model year
    [A-Z\d]             ## Plant
    \d{6}               ## Sequence
    $                   ## to the end of the string
";

if (! REFindNoCase(vinRegex, arguments.v)) {
    return false;
}

这可以大大简化为：

^[A-Z\d]{8}[\dX][A-Z\d]{2}\d{6}$

使用其中任何一个也消除了长度检查的要求，因为正则表达式也会强制执行。

此修改的测试代码：

for (vin in [
    "1GNDM19ZXRB170064",
    "1FAFP40634F172825"
]){
    writeOutput("#vin#: #isVin(vin)#<br />");
}

我将使用详细版本更新 CFLib，因为它更容易理解正在发生的事情，并符合规范。

于 2012-12-20T20:18:10.467 回答