delphi - 为什么编译器会为我的泛型函数参数抱怨“不兼容的类型”？

Question

我在使用泛型时遇到问题。我不知道如何传递OnCallbackWrapper给CallbackWrapper程序。我在以下示例中收到“不兼容的类型”错误：

unit uTest;

interface

uses
  Generics.Defaults;

type
  TGenericCallback<T> = procedure(Fields: T);

type
  TSpecificFields = record
    A: Integer;
    B: Integer;
    C: Integer;
  end;

const
  SpecificFields: TSpecificFields =
  (A: 5; B: 4; C: 3);

procedure CallbackWrapper(GenericCallback: TGenericCallback<TSpecificFields>);

implementation

procedure CallbackWrapper(GenericCallback: TGenericCallback<TSpecificFields>);
begin
  GenericCallback(SpecificFields);
end;

procedure OnCallbackWrapper(const Fields: TSpecificFields);
begin
  Assert(Fields.A = 5);
  Assert(Fields.B = 4);
  Assert(Fields.C = 3);
end;

procedure Dummy;
begin
  CallbackWrapper(OnCallbackWrapper); //Incompatible types here
end;

end.

我究竟做错了什么？谢谢。

Answer 1

您声明的类型按值接收其参数。

TGenericCallback<T> = procedure(Fields: T); // no const

您传递的函数标有const。

procedure OnCallbackWrapper(const Fields: TSpecificFields); // const parameter

因此编译器拒绝您尝试传递的参数不匹配。你需要让双方匹配。例如：

TGenericCallback<T> = procedure(const Fields: T);

Answer 2

procedure OnCallbackWrapper( Fields: TSpecificFields);
begin
  Assert(Fields.A = 5);
  Assert(Fields.B = 4);
  Assert(Fields.C = 3);
end;

或将声明更改为

  TGenericCallback<T> = procedure(const Fields: T);

按值传递参数的过程与通过引用传递参数的过程不兼容。参考