17

我正在从文件中绘制数据。数据点采用公制单位。我想在右侧（y2）显示标准单位的第二个比例。

该文件代表火箭发动机推力随时间的变化。数据以牛顿为单位。我想在左边显示牛顿（这自然会发生），在右边显示磅力。转换是一个简单的因素（将 N 乘以 0.2248 以获得 lbf）。

我可以设置 y2tics，如果我手动设置 y2range，它们会出现在右侧。我不知道如何将 y2range 自动设置为 y1range * 一个因子。

我最终的解决方案是绘制两次，一次在 y1 上以牛顿为单位，一次在 y2 上以磅为单位，并使 y2 绘图几乎不可见：

plot '-' using 1:($2*0.2248) with dots axes x1y2 lc rgb 'white' notitle, \
      '' using 1:2 with lines lc rgb '<color>' title '<title>'

上面的解决方案通常会产生稍微不同的 y 比例：使用 autoragne，gnuplot 会向上取整范围，因此每个轴上的顶部刻度是一个整数，当然不同单位的取整是不同的。

最终，我得到了在每个图中找到最高推力值的 Python 代码，然后我明确地将 yrange 设置为该数字，并将 y2range 设置为该数字 * 0.2248：

f.write("set yrange [0:%s]; set y2range[0:%s]\n" % (peak_thrust, peak_thrust*NEWTON_LBF));

这是最终结果：http ://www.lib.aero/hosted/motors/cesaroni_12-15-12.html （下图示例） 在此处输入图像描述

4

3 回答 3

21

在我看来，最简单的方法是简单地缩放数据：

set y2tics
plot sin(x) w lines, 5*sin(x) w lines axes x1y2

当然，您正在从文件中绘制数据，所以它看起来更像：

set y2tics
FACTOR=0.2248  #conversion factor from newtons to lbf
plot 'datafile' u 1:2 w lines, '' u 1:(FACTOR*$2) w lines

如果您明确设置 yrange（您可能需要这样做）：

set yrange [ymin:ymax]
set y2range [ymin*FACTOR:ymax*FACTOR]

最后，如果你真的想依赖自动缩放，你需要做一些“体操”。

首先，设置一个虚拟终端，这样我们就可以plot不制作情节：

set term unknown
plot 'datafile' u 1:2  #collect information on our data

现在我们已经收集了有关数据的信息，我们可以设置我们的真实y2range

FACTOR=0.2248
set y2range [FACTOR*GPVAL_Y_MIN : FACTOR*GPVAL_Y_MAX]
set y2tics nomirror
set ytics nomirror

现在设置终端并绘制数据：

set term ...
set output ...
plot 'datafile' u 1:2 w lines
于 2012-12-20T13:21:19.673 回答
17

Version 5.0 added support for this kind of relations between the y and y2 (or also x and x2) axis:

set xrange[0:370]
set ytics nomirror
set y2tics
set link y2 via 0.2248*y inverse y/0.2248
plot x

example for <code>set link</code>

于 2014-11-04T14:15:31.610 回答
5

我知道这是一个老问题，答案已经被接受，但我认为值得分享我的方法。

我只是对 x2axis 使用修改后的标签。在你的情况下，这将是

set y2tics ("10" 10/0.2248, "20" 20/0.2248 etc etc...

可以这样循环

do for [i=0:1000:10] { set y2tics add (sprintf("%i",i) i/0.2248) }

for应根据您的数据调整范围的位置（您可以使用和stats变量GPVAL_DATA_Y_MAX完全放心）。不要忘记

set ytics nomirror

这将在（几乎）一个班轮中给出您正在寻找的内容： 在此处输入图像描述

如果您想使用网格并将转换后的因子放在 上x2axis，例如标签 y=50 N 将对应 y2=11.2 （如果您使用网格，它会保持整洁）您可以这样做

do for [i=0:1000:50] { set y2tics add (sprintf("%5.1f",i*0.2248) }

这是结果： 在此处输入图像描述

于 2014-11-04T12:28:31.260 回答