1

有一个数据类型

type
TDataTypeId = (DataTypeId_String, DataTypeId_SmallInt, DataTypeId_Integer, DataTypeId_Word,
               DataTypeId_Boolean, DataTypeId_Float, DataTypeId_Currency,
               DataTypeId_BCD, DataTypeId_FmtBCD, DataTypeId_Date,
               DataTypeId_Time, DataTypeId_DateTime, DataTypeId_TimeStamp,
               DataTypeId_Bytes, DataTypeId_VarBytes, DataTypeId_Blob,
               DataTypeId_Memo, DataTypeId_Graphic, DataTypeId_fmtMemo,
               DataTypeId_FixedChar, DataTypeId_WideChar, DataTypeId_LargeInt,
               DataTypeId_Array, DataTypeId_FixedWideChar, DataTypeId_WideMemo);

有一个函数接受包含此类型值之一的行，返回此值

Function GetType(str: string): TDataTypeId;
var
typeidx: TDataTypeId;
typestr: string;
begin
for typeidx := Low(TDataTypeID) to High(TDataTypeID) do
 begin
  typestr:=GetEnumName(TypeInfo(TDataTypeId),Ord(typeidx));
  typestr:=Copy(typestr, 12, length(typestr)-11);
  //Memo.Lines.Add(typestr+'\n');
  if (AnsiCompareStr(str, typestr)=0) then
     Result:=typeidx
 end;
 end;

结果，有一个程序集

[dcc32 Warning] UnloadProcs.pas(59): W1035 Return value of function 'GetType' might be undefined

如何转换没有出现警告的功能？

4

3 回答 3

5

编译器警告是准确的。如果 if 语句永远不会计算为True，因为没有找到匹配项，则循环不会分配给 Result。然后函数退出而不赋值。

您的选择：

  1. 在循环完成后，为 分配一个值Result，表示未找到匹配项。
  2. 在循环完成后引发异常。

我还建议您exit在分配Result. 当您找到答案时，没有必要继续循环。

我可能会这样写这个函数：

Function GetType(str: string): TDataTypeId;
var
  typestr: string;
begin
  for Result := low(Result) to high(Result) do
  begin
    typestr := GetEnumName(TypeInfo(TDataTypeId),Ord(typeidx));
    typestr := Copy(typestr, 12, length(typestr)-11);
    if AnsiSameStr(str, typestr) then
      exit;
  end;
  raise EEnumNotFound.CreateFmt('Enum not found: %s', [str]);
end;

注意Result变量作为循环变量的使用。这是惯用的，并且有利于减少您声明的局部变量的数量。

我同意您可以使用 更有效地解决您的问题GetEnumValue，但我想向您展示如何以惯用的方式处理编译器警告。

于 2012-12-19T14:14:25.250 回答
1

关于result在这样的循环中使用的一般方式，以下是您可以如何编写函数的方法：

Function GetType(const str: string): TDataTypeId;
var
typestr: string;
begin
 for result := Low(TDataTypeID) to High(TDataTypeID) do
 begin
  typestr:=GetEnumName(TypeInfo(TDataTypeId),Ord(result));
  typestr:=Copy(typestr, 12, length(typestr)-11);
  //Memo.Lines.Add(typestr+'\n');
  if (AnsiCompareStr(str, typestr)=0) then
     exit; // if found, returns result value
 end;
 result := DataTypeId_String; // returns STRING type by default
end;

这是您可以在循环范围之外使用循环变量的唯一情况之一。生成的代码正确且经过优化。

我想你应该更好地定义一个专门的TDataTypeId项目，DataTypeId_Unknown或者如果找不到它就引发一个异常。

于 2012-12-19T14:25:54.697 回答
0

其他人已经解释了警告，但例程的更好实施是这样的：

uses
  TypInfo, ConvUtils;

Function GetType(str: string): TDataTypeId;
var idx: Integer;
begin
  idx := GetEnumValue(TypeInfo(TDataTypeId), 'DataTypeId_'+str);
  if(idx <> -1)then Result := TDataTypeId(idx)
  else RaiseConversionError('Unknown typeID name: '+str);
end;

即无需遍历所有枚举值并将它们作为字符串进行比较，GetEnumValue而是使用该函数。

于 2012-12-19T14:21:25.830 回答