11

我遇到了合并来自不同数据库的两个选择的必要性，即 paradox (in bde) 和 ms sql server。

目前bde（通过TQuery）仅用于程序的这一部分（即dbgrid）。现在我需要将一些存储在 ms sql server 数据库（我通常使用TADOQuery的）中的数据添加到同一个网格中。

尽管查询是在完全不同的表上执行的，但列的结果集的命名和类型相似（我的意思是，如果我有这些表，比如在 ms sql server 数据库中，我可以为此使用一个简单的联合）。

有什么方法可以在 delphi7 中合并从这些中选择的记录集，我可以将结果用作 dbgrid 的数据源？

4

5 回答 5

5

您可以使用由例如定义创建的客户端数据集。SQL-Server 数据集的数据集并添加悖论数据集的数据。TFieldDefArray 在您的情况下可以为空。

type
  TMyFieldDef = Record
    Name: String;
    Size: Integer;
    DataType: TFieldType;
  end;

  TFieldDefArray = array of TMyFieldDef;


function GetClientDSForDS(ADataSet: TDataSet; AFieldDefArray: TFieldDefArray; AClientDataSet: TClientDataSet = nil; WithRecords: Boolean = true)
  : TClientDataSet;
var
  i: Integer;
  Function NoAutoInc(ft: TFieldType): TFieldType;
  begin
    if ft = ftAutoInc then
      Result := ftInteger
    else
      Result := ft;
  end;

begin

  if Assigned(AClientDataSet) then
    Result := AClientDataSet
  else
    Result := TClientDataSet.Create(nil);
  Result.Close;
  Result.FieldDefs.Clear;

  for i := 0 to ADataSet.FieldCount - 1 do
  begin
    Result.FieldDefs.Add(ADataSet.Fields[i].FieldName, NoAutoInc(ADataSet.Fields[i].DataType), ADataSet.Fields[i].Size);
  end;

  for i := 0 to High(AFieldDefArray) do
    Result.FieldDefs.Add(AFieldDefArray[i].Name, AFieldDefArray[i].DataType, AFieldDefArray[i].Size);

  Result.CreateDataSet;
  for i := 0 to ADataSet.FieldCount - 1 do
  begin
    Result.FieldByName(ADataSet.Fields[i].FieldName).DisplayLabel := ADataSet.Fields[i].DisplayLabel;
    Result.FieldByName(ADataSet.Fields[i].FieldName).Visible := ADataSet.Fields[i].Visible;
  end;

  if WithRecords then
  begin
    ADataSet.First;
    while not ADataSet.Eof do
    begin
      Result.Append;
      for i := 0 to ADataSet.FieldCount - 1 do
      begin
        Result.FieldByName(ADataSet.Fields[i].FieldName).Assign(ADataSet.Fields[i]);
      end;
      Result.Post;
      ADataSet.Next;
    end;
  end;
end;

另一种尝试可能是为悖论创建链接服务器，我没有尝试过......

http://www.experts-exchange.com/Microsoft/Development/MS-SQL-Server/SQL_Server_2008/Q_24067488.html

于 2012-12-19T07:36:15.750 回答
4

AnyDAC LocalSQL没问题。您可以使用任何 DataSet 执行 SQL，不仅可以选择 SQL，还可以插入、更新、删除 SQL。

于 2012-12-19T13:24:52.340 回答
3

您可以使用内置TClientDataSet功能通过将第二个数据集的数据附加到第一个数据集的数据来合并数据。

有不同的方法可以做到这一点，我更喜欢一种，因为简单的代码是添加两个 DataSetProvider 并将其链接到您的每个 DataSet，例如

dspBDE.DataSet := MyTQuery;
dspADO.DataSet := MyAdoQuery;

然后，要打开您的数据集，您可以执行以下操作：

MyClientDataSet.Data := dspBDE.Data;
MyClientDataSet.AppendData(dspADO.Data, True);

为了使它起作用，两个数据集都必须匹配字段编号和数据类型。由于您的结构相似，因此如果这不会自动发生，您可以在 SQL 中进行类型转换。

于 2012-12-19T15:04:33.403 回答
2

BDE 支持（或支持）异构查询 这允许查询跨越多个数据集，但 SQL 语法有限。

IIRC 我在十多年前使用了一些快速'n'dirty 数据合并，但我不记得具体细节 - 我已经多年没有接触 BDE。

于 2012-12-19T10:27:15.160 回答
0

几年前（Delphi 7）我使用了 TxQuery，但我不知道它是否仍在开发中

我找到了这个链接

于 2012-12-19T09:19:16.397 回答