10

我已经遵循了一些关于创建自定义属性编辑器对话框的教程，但是涉及的东西太多，我无法让它正常工作。我想要完成的是一个带有日期选择器（日历）、时间选择器以及确定和取消按钮的自定义表单。表单完全没有问题，但是我将如何实现它，以便我可以使用按钮在某种类型的任何组件中发布属性以启动属性编辑器？

我想完全覆盖该TDateTime类型并将我的自定义编辑器放在它的位置，因此无论TDateTime在对象检查器中发布并显示 a 的任何地方，我都可以使用此编辑器在同一个窗口中同时修改日期和时间。

问题是关于创建自定义属性编辑器的文档很差，尽管一些资源非常详尽，但它们涉及的功能过于详细，并且缺乏对最常见场景的理解。

4

1 回答 1

14

我不想在这里问这个问题并期望任何人为我回答，所以我自己做了研究来解决我的问题，我想分享这个迷你项目所涉及的独特经验，因为我相信其他人是对同样的事情感到沮丧。

自定义属性编辑器、对话框和组件编辑器有许多不同的可能性。这尤其需要TDateTimeProperty后代。这将允许您能够直接在对象检查器中以纯文本 (String) 形式编辑属性的值，同时保持 DateTime 格式。

我假设您已经具备创建自定义组件和可以从中发布此属性编辑器的包的一般知识，因为这本身就是一堂课，我不会介绍。这只需要在过程中放置​​一行代码Register，但我们稍后会谈到。

首先，您需要在您的Design-Time包中创建一个新表单，您的组件已在其中注册。命名单元DateTimeProperty.pas，并命名表单DateTimeDialog（从而制作表单的类TDateTimeDialog）。放置您需要的任何控件，在本例中为TMonthCalendar, TDateTimePicker（Kind设置为dtkTime）和 2 个TBitBtn控件，一个标OK有ModalResultof mrOK，另一个标Cancel有ModalResultof mrCancel。

你的单位应该是这样的：

unit DateTimeProperty;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Vcl.ComCtrls, Vcl.StdCtrls, Vcl.Buttons;

type
  TDateTimeDialog = class(TForm)
    dtDate: TMonthCalendar;
    dtTime: TDateTimePicker;
    BitBtn1: TBitBtn;
    BitBtn2: TBitBtn;
  private

  public

  end;         

var
  DateTimeDialog: TDateTimeDialog;

implementation

{$R *.dfm}

end.

这是DFM此表单背后的代码：

object DateTimeDialog: TDateTimeDialog
  Left = 591
  Top = 158
  BorderIcons = [biSystemMenu]
  BorderStyle = bsToolWindow
  Caption = 'Pick Date/Time'
  ClientHeight = 231
  ClientWidth = 241
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  Position = poScreenCenter
  DesignSize = (
    241
    231)
  PixelsPerInch = 96
  TextHeight = 13
  object dtDate: TMonthCalendar
    Left = 8
    Top = 31
    Width = 225
    Height = 166
    Anchors = [akLeft, akRight, akBottom]
    Date = 41261.901190613430000000
    TabOrder = 1
  end
  object dtTime: TDateTimePicker
    Left = 8
    Top = 8
    Width = 113
    Height = 21
    Date = 41261.000000000000000000
    Time = 41261.000000000000000000
    Kind = dtkTime
    TabOrder = 2
  end
  object BitBtn1: TBitBtn
    Left = 158
    Top = 200
    Width = 75
    Height = 25
    Caption = 'OK'
    Default = True
    ModalResult = 1
    TabOrder = 0
  end
  object BitBtn2: TBitBtn
    Left = 77
    Top = 200
    Width = 75
    Height = 25
    Caption = 'Cancel'
    ModalResult = 2
    TabOrder = 3
  end
end

现在，将DesignEditorsand添加DesignIntf到您的uses子句中。确保您已DesignIDE在Requires此Design-Time包中声明。这是发布任何属性编辑器所必需的。

在表单中，使用属性 getter 和 setter创建一个名为DateTimetype的新公共属性。TDateTime此属性将允许您轻松读取/写入TDateTime选择实际代表的完整值。所以你应该在你的表格中有这个：

private
  function GetDateTime: TDateTime;
  procedure SetDateTime(const Value: TDateTime);
public
  property DateTime: TDateTime read GetDateTime write SetDateTime;

....

function TDateTimeDialog.GetDateTime: TDateTime;
begin
  Result:= Int(dtDate.Date) + Frac(dtTime.Time);
end;

procedure TDateTimeDialog.SetDateTime(const Value: TDateTime);
begin
  dtDate.Date:= Value;
  dtTime.DateTime:= Value;
end;

接下来我们需要添加实际的属性编辑器类。在下面创建这个{$R *.dfm}类implementation：

type
  TDateTimeEditor = class(TDateTimeProperty)
  public
    procedure Edit; override;
    function GetAttributes: TPropertyAttributes; override;
    function GetValue: String; override;
    procedure SetValue(const Value: String); override;
  end;

procedure TDateTimeEditor.Edit;
var
  F: TDateTimeDialog;
begin
  //Initialize the property editor window
  F:= TDateTimeDialog.Create(Application);
  try
    F.DateTime:= GetFloatValue;
    if F.ShowModal = mrOK then begin
      SetFloatValue(F.DateTime);
    end;
  finally
    F.Free;
  end;
end;

function TDateTimeEditor.GetAttributes: TPropertyAttributes;
begin
  //Makes the small button show to the right of the property
  Result := inherited GetAttributes + [paDialog];
end;

function TDateTimeEditor.GetValue: String;
begin
  //Returns the string which should show in Object Inspector
  Result:= FormatDateTime('m/d/yy h:nn:ss ampm', GetFloatValue);
end;

procedure TDateTimeEditor.SetValue(const Value: String);
begin
  //Assigns the string typed in Object Inspector to the property
  inherited;
end;

最后，我们需要添加一个Register过程来执行这个新属性编辑器的实际注册：

procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(TDateTime), nil, '', TDateTimeEditor);
end;

现在，在调用RegisterPropertyEditor. 由于第二个和第三个参数是nil一个空字符串，这意味着编辑器将应用于TDateTime. 查看此过程以获取有关使其特定于某些组件和属性实例的更多信息。

这是安装后的最终结果...

最终属性编辑器示例

贡献的自定义属性编辑器的一些好的资源如下：

  1. 如何制作自定义组件属性？
  2. http://delphi.about.com/library/bluc/text/uc092501d.htm
  3. http://www.sandownet.com/propedit.html
于 2012-12-19T02:47:03.350 回答