3

目的是git grep用作 的命令M-x grep，以及随之而来的所有缓冲好处。所需功能：

  • 它读取点的单词/事物作为默认值（完成，排序）
  • 如果设置了区域，它将读取当前区域作为默认参数。

以下是我到目前为止的代码：

(defun bw-read-string-at-point ()
  (interactive)
  (let ((word (word-at-point)))
    (set-text-properties 0 (length word) nil word)
    word))

(defun bw-git-grep (search-str)
  "Uses `git-grep` to find `search-str`"
  (interactive
   (list
    (read-string (format "Search for (%s): " (bw-read-string-at-point)))))
  (let ((search-str (if (= (length search-str) 0)
                        (bw-read-string-at-point) search-str)))
    (grep (concat "git --no-pager grep -i -I -nH --no-color --extended-regexp " search-str))))

我觉得interactive那里有点笨拙，可以做得更好。

4

2 回答 2

4

实际上，它看起来还不错。除了你应该使用default' argument of读取字符串，并且interactiveinbw-read-string-at-point不应该在那里。或者更好的是，只需使用grep-tag-default. 这是我如何调整它：

(defun bw-git-grep (search-str)
  "Uses `git-grep` to find `search-str`"
  (interactive
   (let ((default (grep-tag-default)))
    (list
     (read-string (format "Search for (default %s): " default)
                  nil nil default))))
  (grep (concat "git --no-pager grep -i -I -nH --no-color --extended-regexp " search-str)))
于 2012-12-18T15:04:40.853 回答
1

我会使用read-from-minibuffer而不是read-string：

(defun bw-git-grep (pattern)
  (interactive
   (list
    (read-from-minibuffer
     "Search for: "
     (if (region-active-p)
         (buffer-substring-no-properties (region-beginning) (region-end))
       (thing-at-point 'word)))))

  (let* ((grep-command "git --no-pager grep -i -I -nH --no-color --extended-regexp ")
         (command      (concat grep-command pattern))
         (grep-use-null-device nil))
    (grep command)))

此外，您可能需要确保它grep-use-null-device是 nil 以避免grep附加/dev/null到您的命令（这git似乎不太喜欢）

于 2012-12-18T07:27:01.590 回答