1

我正在使用 2 个 XML 文档，如果变量匹配，则尝试从一个文档中获取一个值到另一个文档中。第一个 XML 文档是一个转换后的电子表格，格式如下：

<Doc1>
    <row>
      <cell>VA15</cell>
      <cell>wr23</cell>
    </row>
    <row>
      <cell>VA45</cell>
      <cell>wr27</cell>
    </row>        <row>
      <cell>VA78</cell>
      <cell>wr24</cell>
    </row>
</Doc1>

第二个 XML 文档较长，其中有一个id元素与电子表格的一部分相匹配：

<Doc2>
 <p> text text text
  <id>wr23</id>
 </p>
</Doc2>

我正在尝试使用我的 xslt 转换来测试该id元素是否与celldoc1 中的 a 的值匹配，它会拉取前面的值cell。在这种情况下，我希望 xslt 转换输出“VA15”。我已经尝试了以下代码的各种排列但没有成功，有人有什么想法吗？

<xsl:for-each select="document('Doc1.xml')//row">
   <xsl:if test="/cell=//id'">
     <xsl:value-of select="/preceding-sibling::cell"/>
   </xsl:if>
</xsl:for-each>
4

2 回答 2

1

基于 Dimitre 的回答，您可以使用key()（用于快速查找）和call-template：

id-lookup.xsl

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:param name="id-lookup-doc">Doc1.xml</xsl:param>
<xsl:variable name="id-to-value-doc" select="document($id-lookup-doc)"/>

<xsl:key name="value-for-id"
    match="/Doc1/row/cell[1]"
    use="../cell[2]" />


<xsl:template name="value-for-id">
    <xsl:param name="id"/>
    <!-- for-each is just to change the context
         to limit results from key() to the lookup document -->
    <xsl:for-each select="$id-to-value-doc">
        <xsl:value-of select="key('value-for-id', $id)"/>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

用值替换 id.xsl

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:import href="id-lookup.xsl"/>

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="id">
    <val>
        <xsl:apply-templates select="@*"/>
        <xsl:call-template name="value-for-id">
            <xsl:with-param name="id" select="text()"/>
        </xsl:call-template>
    </val>
</xsl:template>

</xsl:stylesheet>

当您通过 xslt 处理器运行它时，您将获得所有<id>元素替换为的文档<val>和相应的值。

使用xsltproc，您将像这样运行：

xsltproc id-with-value.xsl Doc2.xml myOtherDoc.xml

您甚至可以使用 xslt 参数更改查找文档：

xsltproc --stringparam id-lookup-doc MyOtherSetOfIdsAndValues.xml id-with-value.xsl Doc2.xml

无论您使用什么 XSLT 处理器，都可以通过某种方式指定模板参数。

于 2012-12-17T21:24:15.320 回答
0 
<xsl:for-each select="document('Doc1.xml')//row">
   <xsl:if test="/cell=//id'">
     <xsl:value-of select="/preceding-sibling::cell"/>
   </xsl:if>
</xsl:for-each>

若干问题：

  1. 这两个文档都没有一个名为的顶级元素cell——而不是绝对表达式，您必须使用相对表达式：

......

cell = //id

和

  preceding-sibling::cell

因为文档节点没有兄弟姐妹。

.2. 具有元素 named 的文档cell没有元素 named id。当 XPath 表达式引用多个文档时，必须显式引用除一个之外的所有文档。进行所有更正后，您的代码将变成这样：

  <xsl:variable name="vthisDoc" select="/"/>

  <xsl:for-each select="document('Doc1.xml')//row">
     <xsl:if test="cell=$vthisDoc//id'">
       <xsl:value-of select="preceding-sibling::cell"/>
     </xsl:if>
  </xsl:for-each>

最后，所有这些都可以简写为：

<xsl:copy-of select=
 "document('Doc1.xml')//row[cell=$vthisDoc//id]/preceding-sibling::cell[1]/text()"/>
于 2012-12-17T18:56:46.477 回答