4

我有两个列表可以说：

def list1 = [a,b,c,d,e...]
def list2 = [1,2,3,4,5... ]

我希望它们以某种模式混合，以便最终列表如下所示： [a,b,c,d,1,2,e,f,g,h,3,4,i,j,k,l,5,6...]

基本上在nlist1 中的每个元素之后，我m从 list2 中获取元素。

编辑：如果一个列表中的元素用完，则剩余列表中的项目应该简单地添加到最终列表中。

EDIT2：两个列表都可以将对象作为元素。

我想找到解决这个问题的最有效方法。

4

2 回答 2

5

这是在 Groovy 中执行此操作的一种方法：

所以我有一个方法mix，它采用整数键（所需元素的数量）和列表作为值的映射：

List mix( Map<Integer,List> amounts ) {
  amounts.collect { k, v ->
    v.collate( k )
  }.transpose().flatten()
}

然后，给定：

// The letters a to z
def list1 = 'a'..'z'

// The numbers 1 to 10
def list2 = 1..10

// Call, and ask for 4 of list1 followed by 2 of list2
mix( [ 4:list1, 2:list2 ] )

返回：

[ 'a', 'b', 'c', 'd', 1, 2,
  'e', 'f', 'g', 'h', 3, 4,
  'i', 'j', 'k', 'l', 5, 6,
  'm', 'n', 'o', 'p', 7, 8,
  'q', 'r', 's', 't', 9, 10 ]

（格式化为在这里更好看）

如您所见，它首先用完数字，当它用完时，列表结束。这是因为当一个列表用完元素时转置停止。

编辑：

用迭代器解决了另一种方法（所以它很懒，不会占用比其他需要更多的内存）：

class MixingIterator<T> implements Iterator<T> {
  private int idx = 0
  private List<Iterator> iter
  private List<Integer>  amts
  
  MixingIterator( List<List> lists, List<Integer> amounts ) {
    iter = lists*.iterator()
    int i = 0
    amts = amounts.collectMany { [ i++ ] * it }
    // OR FOR GROOVY 1.7.8
    // amts = amounts.collect { [ i++ ] * it }.flatten()
  }
  
  private void moveIdx() {
    idx = ++idx % amts.size()
  }
  
  @Override boolean hasNext() {
    iter*.hasNext().any()
  }
  
  @Override T next() {
    if( !hasNext() ) { throw new NoSuchElementException() }
    while( !iter[ amts[ idx ] ].hasNext() ) { moveIdx() }
    T ret = iter[ amts[ idx ] ].next()
    moveIdx()
    ret
  }
  
  @Override void remove() {
    throw new UnsupportedOperationException()
  }
}

您通过以下方式调用它：

def list1 = 'a'..'z'
def list2 = 1..10

def ret = new MixingIterator( [ list1, list2 ], [ 4, 2 ] ).collect()
// OR FOR GROOVY 1.7.8
// def ret = new MixingIterator( [ list1, list2 ], [ 4, 2 ] ).collect { it }

然后 ret 将等于：

['a', 'b', 'c', 'd', 1, 2,
 'e', 'f', 'g', 'h', 3, 4,
 'i', 'j', 'k', 'l', 5, 6,
 'm', 'n', 'o', 'p', 7, 8,
 'q', 'r', 's', 't', 9, 10,
 'u', 'v', 'w', 'x', 'y', 'z']
于 2012-12-17T09:57:13.317 回答
0

我有一个基于主要答案保留剩余元素的功能解决方案。

List mix( Map<Integer,List> amounts ) {
    def maxItems = amounts.collect { k, v -> v.size() }.max()
    amounts.collect { k, v ->
        def padding = maxItems - v.size()
        it.addAll((1..padding).collect { null })
        v.collate( k )
    }.transpose().flatten().grep { it }
}

我在一个简化版本中对其进行了测试，以混合三个列表，一次取一个项目。这个想法只是用空对象添加填充以使所有对象的长度相同。

于 2013-05-14T22:42:31.837 回答