4

在某些情况下，我需要从命令提示符启动和运行 QTP 测试。例如，我想使用 Windows 任务计划程序在整个晚上的不同时间运行 QTP 测试，但是（似乎）没有我可以使用的标志来打开 QTP.exe 并运行测试。我怎样才能做到这一点？

4

2 回答 2

8

确实，使用 QuickTest Pro，您不能通过调用 All hope is not lost来直接运行测试，但是。C:\Program Files (x86)\HP\QuickTest Professional\bin\QTPro.exe "C:\Some Test\"
有一种方法可以创建一个小的 VBS 文件，该文件可以在调用该 VBS 文件时运行任意 QTP 测试。这比为每个测试创建一个批处理文件要好得多。

'*******************************************************************
'RunThisTest
'by Michael Innes
'November 2012

testResourcePath = "C:\Test Logs and Results\"

'Getting the test path
Dim objArgs
Set objArgs = wscript.Arguments
testPath = objArgs(0)

'Determining that the test does exist
Dim objFSO
Set objFSO = CreateObject("Scripting.FileSystemObject")
DoesFolderExist = objFSO.FolderExists(testPath)
Set objFSO = Nothing

If DoesFolderExist Then
    Dim qtApp 'Declare the Application object variable
    Dim qtTest 'Declare a Test object variable
    Set qtApp = CreateObject("QuickTest.Application") 'Create the Application object
    qtApp.Launch 'Start QuickTest
    qtApp.Visible = True 'Make the QuickTest application visible
    qtApp.Open testPath, False 'Open the test in read-only mode
    Set qtTest = qtApp.Test

    'Set qtResultsOpt = CreateObject("QuickTest.RunResultsOptions") ' Create the Run Results Options object
    'qtResultsOpt.ResultsLocation = testResourcePath ' Specify the location to save the test results.
    'qtTest.Run qtResultsOpt,True 'Run the test and wait until end of the test run

    qtTest.Run 'Run the test
    qtTest.Close 'Close the test
    qtApp.Quit
Else
    'Couldn't find the test folder. That's bad. Guess we'll have to report on how we couldn't find the test.
    'Insert reporting mechanism here.
End If

要使用上面的代码，请执行如下命令：cscript.exe "C:\RunThisTest.vbs" "L:\Test Path\The Test Itself\"

于 2012-12-17T02:35:11.457 回答
2

多线程驱动程序工具可以为您执行脚本。

> mdrv.exe -usr "c:\test\foo.usr"
于 2013-08-28T08:44:00.300 回答