1

我是 Excel 的新手。我需要像下面这样的东西。

当用户单击单元格或进入单元格时：

  1. 它应该自动打开/关闭文件窗口。

  2. 当用户选择一个文件时，它应该选择路径/文件名并放入单元格中，比如c:\folder1\file1.ext

  3. 如果用户选择了多个文件，它应该将所有路径/文件名拾取到单元格中，并|作为分隔符。像c:\folder1\file1.ext|d:\folder2\file2.ext

  4. 如果用户第二次单击一个单元格或进入单元格，它应该保留现有的路径/文件名，并允许向它们添加其他路径/文件名，如数字 3

4

2 回答 2

3

这类似于 Sid 的，只是让您双击任何单个单元格以打开文件对话框。

在一个模块中

显示在何处粘贴 getList 代码的图像

Public Function getList(Optional ByVal Target As Range = Nothing) As String
Dim Dialog As FileDialog
Dim File As Integer
Dim Index As Integer

Dim List() As String
Dim Item As Integer
Dim Skip As Boolean

Set Dialog = Application.FileDialog(msoFileDialogFilePicker)

File = Dialog.Show

If File = -1 Then
    ' Get a list of any pre-existing files and clear the cell
    If Not Target Is Nothing Then
        List = Split(Target.Value, "|")
        Target.Value = ""
    End If
    ' Loop through all selected files, checking them against any pre-existing ones to prevent duplicates
    For Index = 1 To Dialog.SelectedItems.Count
        Skip = False
        For Item = LBound(List) To UBound(List)
            If List(Item) = Dialog.SelectedItems(Index) Then
                Skip = True
                Exit For
            End If
        Next Item
        If Skip = False Then
            If Result = "" Then
                Result = Dialog.SelectedItems(Index)
            Else
                Result = Result & "|" & Dialog.SelectedItems(Index)
            End If
        End If
    Next Index
    ' Loop through the pre-existing files and add them to the result
    For Item = UBound(List) To LBound(List) Step -1
        If Not List(Item) = "" Then
            If Result = "" Then
                Result = List(Item)
            Else
                Result = List(Item) & "|" & Result
            End If
        End If
    Next Item
    Set Dialog = Nothing
    ' Set the target output if specified
    If Not Target Is Nothing Then
        Target.Value = Result
    End If
    ' Return the string result
    getList = Result

End If
End Function

在您的工作表代码中

显示在何处粘贴工作表代码的图像

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Rows.Count = 1 And Target.Columns.Count = 1 Then getList Target
End Sub

更新 我改变了 getList 函数（它没有坏，只是让它做得更多）

  • 它将允许您双击任何单元格，这将打开一个文件对话框。
  • 您可以选择 1 个（或更多）文件
  • 文件名将用“|”连接 字符并放入目标单元格
  • 如果单元格中有任何预先存在的文件，则新文件将附加到它们

但是它不支持按回车键打开文件对话框，您必须双击单元格。

更新 以帮助 VMO（评论者）

工作表模块中的代码：

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Rows.Count = 1 And Target.Columns.Count = 1 Then
        If Target.Address = "$A$1" Then ' See Notes Below
            Target.Value = getList(Target)
        End If
    End If
End Sub

要限制可以双击的单元格，您将需要使用类似的东西。您可以更改$A$1为您想要的任何内容或找到一种方法来确定目标范围的名称（不太难）

如果您的工作表未锁定，则单击的单元格将保持焦点，并处于编辑模式，这有点烦人。锁定单元格，在以前版本的 excel 中修复了这个问题（我认为它在 v.2010+ 中不起作用）

模块 (getList) 中的代码可以保持几乎完全相同（尽管您可能希望删除所有处理多个文件的代码，但不是必需的）。您需要做的就是添加一行代码。

.......
Dim Skip As Boolean

Set Dialog = Application.FileDialog(msoFileDialogFilePicker)

Dialog.AllowMultiSelect = False ' This will restrict the dialogue to a single result

File = Dialog.Show

If File = -1 Then
......

希望这会有所帮助，我已经明白你在问什么！

于 2012-12-16T00:52:14.587 回答
1

这应该可以解决问题。第一个子例程是在用户单击单元格时触发的事件。更改第一个if语句中的行号和列号以更改目标单元格。您可以将所有这些代码放入您希望它处理的工作表的代码模块中。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Dim filenames() As String
    Dim filename As Variant
    Dim filelist As String

    ' Make sure the user clicked our target cell

    If Target.Row = 2 And Target.Column = 2 Then

        ' Get a list of filenames

        filenames = GetFileNames

        ' Make sure we got some filenames

        If UBound(filenames) > 0 Then

            ' Go through the filenames, adding each to the output string

            For Each filename In filenames
                filelist = filelist & CStr(filename) & "|"
            Next filename

            ' Remove the final delimiter

            filelist = Left(filelist, Len(filelist) - 2)

            ' Apply the output string to the target cell (adding another
            ' delimiter if there is already text in there)

            If Not Target.Value = "" Then
                Target.Value = Target.Value & "|"
            End If

            Target.Value = Target.Value & filelist

        End If

    End If

End Sub

以下函数被调用以打开文件对话框并检索文件名。

Private Function GetFileNames() As String()

    Dim dlg As FileDialog
    Dim filenames() As String
    Dim i As Integer

    ' Open a file dialogue

    Set dlg = Application.FileDialog(msoFileDialogFilePicker)

    With dlg
        .ButtonName = "Select"                  ' Text of select/open button
        .AllowMultiSelect = True                ' Allows more than one file to be selected
        .Filters.Add "All Files", "*.*", 1      ' File filter
        .Title = "Select file(s)"               ' Title of dialogue
        .InitialView = msoFileDialogViewDetails
        .Show

        ' Redimension the array with the required number of filenames

        ReDim filenames(.SelectedItems.Count)

        ' Add each retrieved filename to the array

        For i = 1 To .SelectedItems.Count
            filenames(i - 1) = .SelectedItems(i)
        Next i

    End With

    ' Clean up and return the array

    Set dlg = Nothing
    GetFileNames = filenames

End Function
于 2012-12-16T00:36:40.897 回答