2

我正在寻找一个类似于 PHP 函数is_numeric()的 Visual FoxPro 函数。
我找到了这个，但是我不能使用VARTYPE或者TYPE因为变量总是一个只包含数字的字符串。

我找到ISDIGIT()了功能，但手册说它只检查第一个字符。

确定指定字符表达式的最左边字符是否为数字（0 到 9）。

  ISDIGIT(cExpression)

参数
cExpression

指定 ISDIGIT( ) 测试的字符表达式。cExpression 中第一个字符之后的任何字符都将被忽略。

我会使用正则表达式对象创建自己的函数VBScript.RegExp

FUNCTION isNumeric( tcValue )
    LOCAL oRE
    oRE = CreateObject("VBScript.RegExp")
    oRE.Pattern = '^[0-9]+$'
    RETURN oRE.test( tcValue )      
ENDFUNC

? isNumeric( '123' )

但是，FoxPro 是否为此提供了任何功能？
我只是俯瞰吗？

同样ISALHPA()决定字符表达式中最左边的字符是否是字母的。我想检查变量是否只包含字母。

4

6 回答 6

5

您可以像这样创建自己的函数。

FUNCTION IsAllDigits
    LPARAMETERS tcSearched, tcOptionalSearch

    * tcSearched = the string of characters to test.
    * tcOptionalSearch = optional, additional characters to allow.

    LOCAL lcSearch
    m.lcSearch = "01234567989" + IIF(VARTYPE(m.tcOptionalSearch) = "C", m.tcOptionalSearch, "")

    LOCAL lcRemaining
    m.lcRemaining = CHRTRAN(m.tcSearched, m.lcSearch, "")

    RETURN ( LEN(m.lcRemaining) = 0 )
ENDFUNC
于 2012-12-14T11:53:22.183 回答
1 
FUNCTION ISNUMERIC
    LPARAMETERS cVal
    LOCAL llNumeric, lnLen, lcChr, lnDecs, lnVal

    llNumeric = VARTYPE(cVal) = "N"      && Donkey has sent a numeric value
    lnDecs = 0

    DO CASE
        CASE llNumeric
        CASE VARTYPE(cVal)<>"C"          && Not a character
        OTHERWISE
            cVal = ALLTRIM(cVal)         && Trim spaces
            lnLen = LEN(cVal)            && How many characters
            llNumeric = .T.              && Assume
            i = 0
            DO WHILE llNumeric AND i<lnLen
                i = i+1
                lcChr = SUBSTR(cVal,i,1)        && Get next char
                    lnVal = VAL(lcChr)
                DO CASE
                CASE lcChr = "0"                && Allowed
                CASE lnVal>0                    && 1 - 9 OK
                CASE INLIST(lcChr, "-", "+")    && Allowed but ONLY at the start
                    llNumeric = i = 1
                CASE lcChr = "."                && Decimal point but ONLY one
                    lnDecs = lnDecs+1
                    llNumeric = lnDecs = 1
                OTHERWISE
                    llNumeric = .F.
            ENDCASE
        ENDDO
    ENDCASE
    RETURN llNumeric
ENDFUNC
于 2012-12-21T09:00:38.573 回答
1

这可能适用于 ISDIGIT() 或 ISALPHA()。

Function IsAllDigits(myValue)
   lReturn = .t. 
   FOR i = 1 TO LEN(myvalue)
      IF !ISDIGIT( SUBSTR(myValue, i, 1)  )
         lReturn = .f.
         EXIT
      ENDIF
   ENDFOR
   RETURN lReturn
ENDFUNC
于 2013-03-01T16:04:56.720 回答
1

一个班轮怎么样？

Function IsNumeric
Lparameters pString
Return  m.pString == Chrtran(m.pString, Chrtran(m.pString, "0123456789", ""), "")
EndFunc

您可以将任何其他有效字符改为“0123456789”，如“.”。或者 ”，”

于 2013-03-03T12:14:05.990 回答
1

测试字符串是否为数字更简单：

  • 如果 String="123" => val('String')>0
  • 如果 String="AB123" => val('String')=0

就这样...

于 2013-09-16T12:38:37.730 回答
0

仅使用 Visual Fox Pro，您可以执行以下操作：

FUNCTION is_numeric(var_name)
    error_trigger=.f. &&** first initialization 
    &&** evaluate("any_char") will generate an error so I'm using TRY-CATCH-ENDTRY  
    TRY  
      EVALUATE(var_name)
    CATCH &&** evaluate() generates an error then the string is character
      WAIT WINDOW "character"   
      error_trigger=.t. &&** there was an error returned by evaluate()
      EXIT  && stop and jump after ENDTRY
    ENDTRY 
    IF error_trigger=.f. &&** there was no error returned by evaluate() then the string was numeric
       WAIT WINDOW "numeric"
    ENDIF 
ENDFUNC

然后调用函数：
is_numeric("333") 将显示： numeric
is_numeric("aaa") 将显示： character
is_numeric("333a333") 将显示： character
希望对您有所帮助

于 2013-03-01T08:28:38.027 回答