1

作为 Excel 编程的新手，我在网上搜索了一个函数/UDF/VBA，我可以在 Excel 中使用它来查找单元格中的子字符串并在此单元格中加粗/着色。

我下面有这种表。- A 列包含要部分格式化的文本， - B 列包含我要查找的子字符串， - C 列包含子字符串 (B) 在字符串 (A) 中的位置

          A          B         C
1  ABCDEFGHIJKLM   FGHI      6-9
2  NOPQRSTUVWXYZ   UVWXY     8-12
...

这里我需要获得：

          A          B         C
1  ABCDE**FGHI**JKLM   FGHI      6-9
2  NOPQRST**UVWXY**Z   UVWXY     8-12
...

是否可以将其应用于整列而不是仅行。

任何帮助或建议将不胜感激。谢谢 ！

4

1 回答 1

1 
' just add a loop and some checkings
Sub t()

Dim heightA As Long
Dim heightB As Long
Dim height As Long
Dim i As Long

heightA = Cells(Rows.Count, 1).End(xlUp).Row
heightB = Cells(Rows.Count, 2).End(xlUp).Row
If heightA < heightB Then
    height = heightA
Else
    height = heightB
End If

If height > 1 Then
    For i = 1 To height
        Range("A" & i).Font.Bold = False
        ''Replace the formula with the full string
        Range("A" & i) = Range("A" & i).Value
        'Find the starting position of the string in B within the string produced by the formula
        If Range("B" & i).Value <> "" Then
            myPos = InStr(1, Range("A" & i).Value, Range("B" & i).Value, 1)
            If myPos > 0 Then
                'Bold the string from B column
                Range("A" & i).Characters(myPos, Len(Range("B" & i).Value)).Font.Bold = True
            End If
        End If
    Next i
End If
End Sub

编辑：使用 MASTER_STR、SUBSTR1、POS1(START-END)、SUBSTR2、POS2 等格式的 POSITION

Sub t()

Dim heightA As Long
Dim heightB As Long
Dim height As Long
Dim i As Long
Dim length As Long
Dim tmp
Dim width As Long
heightA = Cells(Rows.Count, 1).End(xlUp).Row
heightB = Cells(Rows.Count, 2).End(xlUp).Row
If heightA < heightB Then
    height = heightA
Else
    height = heightB
End If

If height > 1 Then
    For i = 1 To height
        Range("A" & i).Font.Bold = False
        ''Replace the formula with the full string
        Range("A" & i) = Range("A" & i).Value
        'Find the starting position of the string in B within the string produced by the formula
        width = Cells(i, Columns.Count).End(xlToLeft).Column
        If width >= 3 Then
            For j = 3 To width Step 2
            If Cells(i, j).Value <> "" Then
                    tmp = Split(Cells(i, j).Value, "-")
                    myPos = CLng(tmp(0))
                    length = CLng(tmp(1)) - myPos + 1
                    'myPos = InStr(1, Range("A" & i).Value, Range("B" & i).Value, 1)
                    If myPos > 0 Then
                        'Bold the string from B column
                        Range("A" & i).Characters(myPos, length).Font.Bold = True
                    End If
                End If
            Next j
        End If
    Next i
End If
End Sub

样本输入

ABCDEFG A   1-1 C   3-5
ABCDEFG A   1-1 C   3-3
于 2012-12-13T05:13:46.563 回答