27

我有一个保存为 UTF-8 的文本文件，当我尝试读取该文件时，它给了我奇怪的字符而不是正确的字符（它包含中文字符）。我怎样才能让它给我正确的汉字？

Option Explicit

Dim objFSO, strTextFile, strData, strLine, arrLines, aniTextFile, aniData, aniLines, aniLine, objTextFile, fso, inputFileList, listFile, fname
Dim iim1, iret, iret2, iret3, i
Const ForReading   = 1

Set objFSO = CreateObject("Scripting.FileSystemObject")
strTextFile = "C:\Users\admin\Desktop\ArtistCG\folder.txt"
strData = objFSO.OpenTextFile(strTextFile,ForReading).ReadAll
arrLines = Split(strData,vbCrLf)

aniTextFile = "C:\Users\admin\Desktop\ArtistCG\folder-list.txt"
aniData = objFSO.OpenTextFile(aniTextFile,ForReading).ReadAll
aniLines = Split(aniData,vbCrLf)

For i = 0 To UBound(arrLines)
  strData = objFSO.OpenTextFile(arrLines(i),ForReading).ReadAll
  WScript.Echo strData

  Set listFile = objFSO.OpenTextFile(aniLines(i),ForReading)
  Do While Not listFile.AtEndOfStream
    fName = listFile.ReadLine
    WScript.Echo fName
  Loop
  listFile.Close
Next
4

2 回答 2

54

从文档中：

FSO 只能读取 ASCII 文本文件。您不能使用 FSO 读取 Unicode 文件或读取 Microsoft Word 或 Microsoft Excel 等二进制文件格式。

既然你有奇怪的字符，我想这有点不正确，并且文件是在一些 8 位 Windows 代码页中读取的，因为如果它真的只能读取 ASCII，你会看到????

无论如何，如果你可以使用ADO，你可以这样做：

Dim objStream, strData

Set objStream = CreateObject("ADODB.Stream")

objStream.CharSet = "utf-8"
objStream.Open
objStream.LoadFromFile("C:\Users\admin\Desktop\ArtistCG\folder.txt")

strData = objStream.ReadText()

objStream.Close
Set objStream = Nothing
于 2012-12-13T07:48:17.150 回答
-5

使用文件系统对象时，您可以使用 , True 来读取 UTF 8 格式的文件。

sFile = "C:\Users\admin\Desktop\ArtistCG\folder.txt"
Set FS = CreateObject("scripting.filesystemobject")
Set oReadfile = FS.OpenTextFile(sFile, 1, False, True)
TextFromFile = sReadfile.ReadAll
于 2013-03-14T23:29:05.027 回答