1

当我不知道节点的名称时，如何使用 XSTL 转换 XML 文档。所以基本上它应该适用于任何 XML 文档。

假设我得到了这个 XML 文档：

<?xml version="1.0"?>
<?xml-stylesheet href="transform.xsl" type="text/xsl" ?>
<!DOCTYPE cinema [
<!ELEMENT a (b*)>
<!ELEMENT b (c,d,e)>
<!ELEMENT c (#PCDATA)>
<!ELEMENT d (#PCDATA)>
<!ELEMENT e (#PCDATA)>
]>

<cinema>
<movie>
    <actor>Some actor</actor>
    <title>Some title</title>
    <year>Some year</year>
</movie>
</cinema>

我将如何从中创建一个 HTML 表格？我知道我可以像这样匹配根元素：

<xsl:template match="/">

然后我选择所有这样的电影：

<xsl:for-each select="/*/*">

但是我怎么知道每部电影有一行，演员，标题和年份三列？特别是因为 XML 文件（电影）应该只能有 2 个孩子或 5 个孩子。

+++编辑+++

如果我这样做：

<tr>
    <td><xsl:value-of select="."/></td>
</tr>

我将每部电影的详细信息排成一行。这几乎接近我想要实现的目标。但是我如何在该行的三列中展开电影细节？

4

3 回答 3

2

如果您知道您将始终具有三个级别的元素（根、子和孙），那么应该这样做：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="html" />

  <xsl:template match="/">
    <html><body><xsl:apply-templates /></body></html>
  </xsl:template>

  <xsl:template match="/*">
    <table><xsl:apply-templates /></table>
  </xsl:template>

  <xsl:template match="/*/*">
    <tr><xsl:apply-templates /></tr>
  </xsl:template>

  <xsl:template match="/*/*/*">
    <td><xsl:apply-templates /></td>
  </xsl:template>
</xsl:stylesheet>

/模板匹配文档节点，匹配文档节点的/*一级元素子节点（即文档的根元素），/*/*匹配二级子节点等。

<xsl:apply-templates/>（不带 no select）将匹配模板应用于当前节点的所有子节点，包括子元素、文本节点、注释和处理指令。因此，您可能需要将根模板

  <xsl:template match="/">
    <html><body><xsl:apply-templates select="*" /></body></html>
  </xsl:template>

只选择子元素。

于 2012-12-12T14:40:58.833 回答
1

示例 XML： 

<?xml version="1.0" encoding="utf-8"?>
<cinema>
  <movie>
    <actor>Some actor</actor>
    <title>Some title</title>
    <year>Some year</year>
  </movie>
  <movie>
    <actor>Someother actor</actor>
    <title>Someother title</title>
    <year>Someother year</year>
  </movie>
</cinema>

XSLT：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/">
      <table>
        <xsl:for-each select="*/*">
          <xsl:if test="position()=1">
            <tr>
              <th>actor</th>
              <th>title</th>
              <th>year</th>
            </tr>
          </xsl:if>
          <tr>
            <xsl:for-each select="actor|title|year">
              <td>
                <xsl:value-of select="."/>
              </td>
            </xsl:for-each>
          </tr>
        </xsl:for-each>
      </table>
    </xsl:template>
</xsl:stylesheet>

输出：

<?xml version="1.0" encoding="utf-8"?>
<table>
  <tr>
    <th>actor</th>
    <th>title</th>
    <th>year</th>
  </tr>
  <tr>
    <td>Some actor</td>
    <td>Some title</td>
    <td>Some year</td>
  </tr>
  <tr>
    <td>Someother actor</td>
    <td>Someother title</td>
    <td>Someother year</td>
  </tr>
</table>
于 2012-12-12T14:48:30.727 回答
0

使用：

<xsl:template match="movie">
 <!-- Specify your tr-producing code here -->
</xsl:template>
于 2012-12-12T14:14:50.737 回答