0

我正在尝试在 Verilog 中将十六进制转换为 BCD。我没有使用任何时钟。在我的程序中，我一次输入一个输入并将其转换并显示结果。但是，我的程序给出了未定义的结果。我该如何解决？

module HexToBCD(num,result);

input num;

output [7:0]result;

assign result[0]=num%2;
assign num=num/2;

assign result[1]=num%2;
assign num=num/2;

assign result[2]=num%2;
assign num=num/2;

assign result[3]=num%2;
assign num=num/2;

assign result[4]=num%2;
assign num=num/2;

assign result[5]=num%2;
assign num=num/2;

assign result[6]=num%2;
assign num=num/2;

assign result[7]=num%2;
assign num=num/2;

endmodule
4

2 回答 2

1

我看到你的模块有一些不寻常的事情。

  1. num是 1 位宽，但您试图将其除以 2。

  2. 您正在分配给input.

  3. 你做同样的任务num8次。Verilog 不是这样工作的。所有连续分配都被并行评估。

于 2012-12-12T15:27:45.693 回答
0

以下代码将 8 位二进制数转换为等效的 BCD。有关该算法的说明，请参阅此链接。

module bcd (
    input [7:0] binary,
    output reg [3:0] hundreds,
    output reg [3:0] tens,
    output reg [3:0] ones);

integer i;
always @(binary) begin
    // set 100's, 10's, and 1's to zero
    hundreds = 4'd0;
    tens = 4'd0;
    ones = 4'd0;

    for (i=7; i>=0; i=i-1) begin
        // add 3 to columns >= 5
        if (hundreds >= 5)
            hundreds = hundreds + 3;
        if (tens >= 5)
            tens = tens + 3;
        if (ones >= 5)
            ones = ones + 3;

        // shift left one
        hundreds = hundreds << 1;
        hundreds[0] = tens[3];
        tens = tens << 1;
        tens[0] = ones[3];
        ones = ones << 1;
        ones[0] = binary[i];
    end
end
endmodule
于 2013-01-12T12:15:14.623 回答