delphi - 迭代编辑框并将值与Delphi中的先前值进行比较

Question

我正在做一个学校项目，我有 10 个文本框（5 对）。

这个想法是每对的总和最多可以是“3”。所以

[1] [2]

[1] [0]

...

[2] [1]

我认为在“onChange”事件期间检查这个太费时了，所以我决定用一个按钮来检查所有这些。只要任何一对不满足要求，它就会抛出一个 showmessage() 。

现在有没有办法检查每一对并检查它们的值是否小于或等于三并且不是负数？我知道我可以通过编写大量代码来手动完成，但我希望尽可能保持干净。

谢谢！

Answer 1

在一个窗体上放置十个TEdit控件。由于您是手动创建的，因此您需要使它们在代码中易于访问，并且没有超级优雅的方法可以做到这一点。但这有效：

在您的实施部分，定义

type
  TEditorPair = record
    First,
    Second: TEdit;
  end;

FEditors: array[0..4] of TEditorPair;并向您的表单类添加一个私有字段。做

procedure TForm1.FormCreate(Sender: TObject);
begin
  FEditors[0].First := Edit1;
  FEditors[0].Second := Edit2;
  FEditors[1].First := Edit3;
  FEditors[1].Second := Edit4;
  FEditors[2].First := Edit5;
  FEditors[2].Second := Edit6;
  FEditors[3].First := Edit7;
  FEditors[3].Second := Edit8;
  FEditors[4].First := Edit9;
  FEditors[4].Second := Edit10;
end;

现在，选择所有十个编辑器控件，OnChange并向它们添加一个公共事件。

procedure TForm1.EditorChange(Sender: TObject);

  procedure FailPair(PairIndex: integer);
  begin
    FEditors[PairIndex].First.Color := clRed;
    FEditors[PairIndex].Second.Color := clRed;
  end;

  procedure PassPair(PairIndex: integer);
  begin
    FEditors[PairIndex].First.Color := clWindow;
    FEditors[PairIndex].Second.Color := clWindow;
  end;

var
  i: Integer;
  n1, n2: integer;
begin
  for i := 0 to high(FEditors) do
  begin
    if (FEditors[i].First.Text = '') or (FEditors[i].Second.Text = '') then
      Continue;
    if TryStrToInt(FEditors[i].First.Text, n1) and TryStrToInt(FEditors[i].Second.Text, n2) then
      if InRange(n1+n2, 0, 3) then
        PassPair(i)
      else
        FailPair(i)
    else
      FailPair(i);
  end;
end;

示例编译EXE

如果您要打高尔夫球，EditorChange程序可以缩短到

procedure TForm1.EditorChange(Sender: TObject);

  procedure PairFeedback(PairIndex: integer; Pass: boolean);
  const
    Colors: array[boolean] of TColor = (clRed, clWindow);
  begin
    FEditors[PairIndex].First.Color := Colors[Pass];
    FEditors[PairIndex].Second.Color := Colors[Pass];
  end;

var
  i: Integer;
  n1, n2: integer;
begin
  for i := 0 to high(FEditors) do
  begin
    if (FEditors[i].First.Text = '') or (FEditors[i].Second.Text = '') then
      Continue;
    PairFeedback(i, TryStrToInt(FEditors[i].First.Text, n1) and
      TryStrToInt(FEditors[i].Second.Text, n2) and InRange(n1+n2, 0, 3));
  end;
end;

我们使用了一些“技巧”，例如布尔短路（惰性）评估。