1

我有一个带有一些 Javascript 的 HTML 页面，我正在尝试使用 XSLT 1.0 进行解析。我想修改 Javascript 中的 URL 以使路径成为绝对路径而不是相对路径。

Javascript 代码大致如下所示：

<html>
    <head>
        <script>
            function login() {
                window.location = '{@myBase}/myloginpage';
            }
        </script>
    </head>

    <body>
     ...
    </body>
</html>

我希望将“{@myBase}”替换为我的域。我觉得我非常偏离了方向。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:proxy="java:senselogic.sitevision.portlet.proxy.web.ProxyFunctions" 
   extension-element-prefixes="proxy">


   <xsl:import href="template.xsl"/>

    <xsl:template match="//script/text()">
        <xsl:variable name="mypath">
          <xsl:call-template name="string-replace-all">
            <xsl:with-param name="text"><xsl:value-of select="{@myBase}"/></xsl:with-param>
            <xsl:with-param name="replace">{@myBase}</xsl:with-param>
            <xsl:with-param name="by">http://www.mydomain.com</xsl:with-param>
          </xsl:call-template>
        </xsl:variable>
    </xsl:template>    



    <xsl:template name="string-replace-all">
      <xsl:param name="text" />
      <xsl:param name="replace" />
      <xsl:param name="by" />
      <xsl:choose>
        <xsl:when test="contains($text, $replace)">
          <xsl:value-of select="substring-before($text,$replace)" />
          <xsl:value-of select="$by" />
          <xsl:call-template name="string-replace-all">
            <xsl:with-param name="text"
            select="substring-after($text,$replace)" />
            <xsl:with-param name="replace" select="$replace" />
            <xsl:with-param name="by" select="$by" />
          </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="$text" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:template>    
</xsl:stylesheet>
4

1 回答 1

2

其实，你离得不远了。

首先，您正在定义一个变量<xsl:variable name="mypath">来保存调用模板的结果，但实际上并未对其进行任何操作。我认为您根本不需要将其包装在变量声明中。

其次，您没有将正确的值传递给text参数。而不是这样做

<xsl:with-param name="text"><xsl:value-of select="{@myBase}"/></xsl:with-param>

做这个

<xsl:with-param name="text"><xsl:value-of select="."/></xsl:with-param>

或者更好的是，这个：

<xsl:with-param name="text" select="."/>

试试这个 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:proxy="java:senselogic.sitevision.portlet.proxy.web.ProxyFunctions" extension-element-prefixes="proxy">
    <xsl:param name="domain" select="'http://www.mydomain.com'"/>

    <xsl:template match="//script/text()">
        <xsl:call-template name="string-replace-all">
            <xsl:with-param name="text" select="."/>
            <xsl:with-param name="replace" select="'{@myBase}'" />
            <xsl:with-param name="by" select="$domain"/>
        </xsl:call-template>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template name="string-replace-all">
        <xsl:param name="text"/>
        <xsl:param name="replace"/>
        <xsl:param name="by"/>
        <xsl:choose>
            <xsl:when test="contains($text, $replace)">
                <xsl:value-of select="substring-before($text,$replace)"/>
                <xsl:value-of select="$by"/>
                <xsl:call-template name="string-replace-all">
                    <xsl:with-param name="text" select="substring-after($text,$replace)"/>
                    <xsl:with-param name="replace" select="$replace"/>
                    <xsl:with-param name="by" select="$by"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$text"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

（请注意，我还将您的域设置为参数）

当应用于您的 XHTML 时，将输出以下内容

<html>
<head>
<META http-equiv="Content-Type" content="text/html">
<script>
            function login() {
                window.location = 'http://www.mydomain.com/myloginpage';
            }
        </script></head>
<body>
     ...
    </body>
</html>
于 2012-12-11T11:07:32.987 回答