perl - 如何在 Perl 程序中暂时抑制 STDOUT？

Question

有什么简单的方法可以告诉 perl“现在忽略打印的所有内容”？

我必须在外部 Perl 模块中调用一个过程，但是该过程会打印很多不必要的信息（全部通过标准print）。

我知道select可以用来以某种方式重定向它，但我在阅读perldoc时不太明智。

编辑：我很快就找到了答案，但我会添加一个示例以使其更清楚（但我猜并不多）

use TectoMT::Scenario;
use TectoMT::Document;

sub tagDocuments {
    my @documents = @_;

    my $scenario = TectoMT::Scenario->new({'blocks'=> [ qw(
            SCzechW_to_SCzechM::Sentence_segmentation 
            SCzechW_to_SCzechM::Tokenize  
            SCzechW_to_SCzechM::TagHajic
            SCzechM_to_SCzechN::Czech_named_ent_SVM_recognizer) ]});

    $scenario->apply_on_tmt_documents(@documents);
    return @documents;
}

TectoMT::Scenario 和 TectoMT::Document 是那些外部模块

Answer 1

我自己的回答：

use IO::Null;

print "does print.";

my $null = IO::Null;
my $oldfh = select($null); 

print "does not print.";

select($oldfh);

print "does print.";

Answer 2

我意识到这已经得到解答，但我认为值得了解另一种方法。特别是如果某些东西一心想要打印到STDOUT……</p>

# Store anything written to STDOUT in a string.
my $str;
open my $fh, '>', \$str;
{
  local *STDOUT = $fh;
  code_that_prints_to_stdout();
}

关键位是local *STDOUT。STDOUT它用您选择的文件句柄替换 normal ，但仅适用于包含local的块的范围。

Answer 3

参考这里和其他线程上的一些答案，我想出了这个；

use strict;
use warnings;
use File::Spec;

sub my_functor { system("some_noisy_command.exe", "--option1", "--option2"); }
silently(\&my_functor);

其中“silently()”采用函子并使用重定向的 stdout 运行它：

sub silently($) {
    #Turn off STDOUT
    open my $saveout, ">&STDOUT";
    open STDOUT, '>', File::Spec->devnull();

    #Run passed function
    my $func = $_[0];
    $func->();

    #Restore STDOUT
    open STDOUT, ">&", $saveout;
}

Answer 4

open my $saveout, ">&STDOUT";
open STDOUT, '>', "/dev/null";

(do your other stuff here)

open STDOUT, ">&", $saveout;

Answer 5

如果你只想使用标准库中的模块，File::Spec有这个devnull()功能。它返回一个字符串，表示您可以用它打开的空设备（"/dev/null"在 *nix 上）open()。