1

我有以下模板：

<xsl:template match="footnote">
    <xsl:variable name = "string">
        <xsl:value-of select="."/>
    </xsl:variable>
    <xsl:variable name = "bool">
        <xsl:if test="$string = preceding-sibling::node()/$string">
            <xsl:text>false</xsl:test>
        </xsl:if>
    </xsl:variable>
    <xsl:if test="$bool != 'false'">
        <!-- DO STUFF -->
    </xsl:if>
</xsl:template>

我正在尝试检查当前节点的 $string 变量并将其与所有先前的脚注节点进行检查，以查看它们是否具有相同的 $string 变量。如果它与前面的任何兄弟姐妹都不匹配，那么它应该做一些事情，否则它什么也不做。

使用我拥有的代码，即使尚未创建脚注节点，测试 "$string = previous-sibling::node()/$string" 也始终评估为 true。

谁能帮我吗？我很难创建表达式来与所有先前兄弟姐妹中的变量进行比较。

编辑：示例 XML：

<xml>
<footnote>Footnote 1</footnote>
<footnote>Footnote 2</footnote>
<footnote>Footnote 1</footnote>
<footnote>Footnote 1</footnote>
<footnore>Footnote 3</footenote>
</xml>

我正在尝试将其转换为：

<xml>
<footnote>Footnote 1</footnote>
<footnote>Footnote 2</footnote>
<footnote>Footnore 3</footnore>
</xml
4

5 回答 5

5

出色地。发布您的输出 XML 使其更加清晰！你去解决方案：

示例 XML：

<?xml version="1.0" encoding="utf-8"?>
<root>
  <footnote>Matching</footnote>
  <footnote>Example1</footnote>
  <footnote>Matching</footnote>
  <footnote>Example2</footnote>
  <footnote>Example3</footnote>
</root>

和 XSL：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>
  <xsl:template match="footnote[.=preceding-sibling::footnote/.]"/>
</xsl:stylesheet>

结果：

<?xml version="1.0" encoding="utf-8"?>
<xml>
  <footnote>Matching</footnote>
  <footnote>Example1</footnote>
  <footnote>Example2</footnote>
  <footnote>Example3</footnote>
</xml>
于 2012-12-07T14:47:46.067 回答
2

假设您想检查当前脚注的值text()与前一个脚注text()'s的唯一性，那么您只需检查preceding-sibling::node()'s text()：

<xsl:if test="$string = preceding-sibling::node()/text()">

例如

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0"
                >
    <xsl:output omit-xml-declaration="yes" method="xml" version="1.0" indent="yes" />

    <xsl:template match="/xml">
        <xml>
            <xsl:apply-templates select="footnote" />
        </xml>
    </xsl:template>

    <xsl:template match="footnote">
        <xsl:variable name = "string">
            <xsl:value-of select="./text()"/>
        </xsl:variable>
        <xsl:variable name = "bool">
            <xsl:if test="$string = preceding-sibling::node()/text()">
                <xsl:text>false</xsl:text>
            </xsl:if>
        </xsl:variable>
        <xsl:if test="$bool != 'false'">
            <xsl:copy-of select="."></xsl:copy-of>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

将输入：

<xml>
    <footnote>
        someVal
    </footnote>
    <footnote>
        anotherVal
    </footnote>
    <footnote>
        anotherVal
    </footnote>
    <footnote>
        newVal
    </footnote>
</xml>

进入：

<xml>
  <footnote>
        someVal
    </footnote>
  <footnote>
        anotherVal
    </footnote>
  <footnote>
        newVal
    </footnote>
</xml>

如果您的意图是识别元素中的组，您还应该查看 Muenchian 分组。

于 2012-12-07T14:54:20.693 回答
1

你可以使用

<xsl:template match="footnote[not(. = preceding-sibling::footnote)]">

创建仅针对给定脚注字符串的第一个实例触发的模板。. = preceding-sibling::footnote如果此节点的字符串值与其前面的任何兄弟节点的字符串值相同，则为真，如果与所有not(....)兄弟节点不同，则为真。

但是对于大型文档，这将是相当低效的（脚注元素数量的二次方）。最好使用<xsl:for-each-group>(XSLT 2.0) 或 Muenchian Grouping (XSLT 1.0)footnote按字符串值对元素进行分组，并从每个组中提取第一个元素。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:key name="fn" match="footnote" use="." />

  <!-- Ignore all but the first footnote for a given value -->
  <xsl:template match="footnote[generate-id() != generate-id(key('fn', .)[1])]" />

  <!-- copy everything else verbatim -->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>
于 2012-12-07T14:54:38.030 回答
0

在 XSLT 2.0 中，您有一个 distinct-values 函数：

<xsl:for-each select="distinct-values(footnote)">
    <footnote><xsl:value-of select="."/></footnote>
</xsl:for-each>
于 2012-12-09T22:49:34.710 回答
0 

<xsl:template match="footnote">

    <xsl:variable name = "string">
      <xsl:value-of select="./text()"/>
    </xsl:variable>
    <xsl:variable name = "bool">
      <xsl:if test="$string != preceding-sibling::node()/text()">
        <xsl:text>false</xsl:text>
    </xsl:if>
    </xsl:variable>
    <xsl:if test="$bool != 'false'">
        true
    </xsl:if>
  <xsl:if test="$bool = 'false'">
    false
  </xsl:if>
  </xsl:template>

于 2012-12-07T15:05:25.763 回答