4

我正在尝试解析以下 BibTeX 文件（bibliography.bib）：

@book{Lee2000a,
abstract = {Abstract goes here},
author = {Lee, Wenke and Stolfo, Salvatore J},
title = {{Data mining approaches for intrusion detection}},
year = {2000}
}
@article{Forrest1996,
abstract = {Abstract goes here},
author = {Forrest, Stephanie and Hofmeyr, Steven A. and Anil, Somayaji},
title = {{Computer immunology}},
year = {1996}
}

我正在使用BibTeX::Parser按预期工作的包，问题是创建哈希结构的哈希。这是我的代码：

#!/usr/bin/perl
# http://search.cpan.org/~gerhard/BibTeX-Parser-0.62/lib/BibTeX/Parser.pm
use BibTeX::Parser;
use IO::File;
use Data::Dumper;
use strict;
use warnings;

my $filename="bibliography.bib";
my (%bibliography, %article);
my $i;
my ($entry, @entries, $type, $key);
my (my $hkey, my $hvalue);

# open BibTeX
my $fh = IO::File->new("$filename") or die "could not open $filename: $!\n";

# create parser object ...
my $parser = BibTeX::Parser->new($fh);

# ... and iterate over entries
while ($entry = $parser->next ) {
  if ($entry->parse_ok) {

    # return BibTeX elements like abstract, author, title ...
    @entries = $entry->fieldlist();

    # create %article as a hash array e.g. year -> 1996; isbn -> 1581138709 etc.
    foreach (@entries) {
      $article{"$_"} = $entry->field("$_");
    }

    # return article's key (Lee2000a, Forrest1996)
    $key = $entry->key;

    # append %article into %bibliography with approporiate key
    $bibliography{"$key"} = \%article;

    #Debug
    #print $entry->key, "\n";
    #print Dumper (\%article);

    # removes all elements of %article (prepare for next iteration)
    %article = ();

    #Debug
    #print "================================\n";
  }

  else {
    warn "Error parsing file: " . $entry->error;
 }
}

    #Debug
    #print Dumper (\%bibliography);

当前输出Dumper (\%bibliography)：

$VAR1 = {
          'Lee2000a' => {},
          'Forrest1996' => $VAR1->{'Lee2000a'}
        };

期望的输出Dumper (\%bibliography)：

$VAR1 = {
          'Lee2000a' => {
                'abstract' => 'Abstract goes here',
                'author' => 'Lee, Wenke and Stolfo, Salvatore J'
                'title' => 'Data mining approaches for intrusion detection'
                'year' => '2000'
              },
          'Forrest1996' => {
                'abstract' => 'Abstract goes here',
                'author' => 'Forrest, Stephanie and Hofmeyr, Steven A. and Anil, Somayaji'
                'title' => 'Computer immunology'
                'year' => '1996'
                }
        };

我在做什么错？非常感谢。

4

2 回答 2

2

在没有此行的情况下尝试您的代码：

# removes all elements of %article (prepare for next iteration)
%article = ();

您已将 $bibilography{$key} 设置为对该哈希的引用，然后将其清空。

另外，将 %article 的声明移到循环中（可能就在 之后if ($entry->parse_ok) {，以便它的范围在您使用它的地方是本地的，并且不需要重新初始化它。

希望有帮助...

更新以包括排序问题...这应该可以对您的哈希进行排序：

foreach my $bib_key ( sort keys %bibliography ) {
  print "$bib_key\n";

  foreach my $article_key (sort keys %{ $bibliography{$bib_key} }) {
    print "\t $article_key: $bibliography{$bib_key}{$article_key}\n";
  }
}
于 2012-12-07T14:05:07.193 回答
1

翻斗机输出

$VAR1 = { 'Lee2000a' => {}, 'Forrest1996' => $VAR1->{'Lee2000a'} };

表明您的哈希是共享结构，即，$bibliography->{Lee2000a}并且$bibliography->{Forrest1996}是对同一文章哈希的引用。您的代码具有my %article外部范围，并且循环的每次迭代都会清除并重新填充此共享哈希。

相反，您希望每次迭代都创建一个新的内部文章哈希。移除外层%article并将其移入循环中——下面标记为 (+)。删除该%article = ()行，这将破坏您刚刚收集的数据。

while ($entry = $parser->next) {
  if ($entry->parse_ok) {
    # return BibTeX elements like abstract, author, title ...
    @entries = $entry->fieldlist();

    # create %article as a hash array e.g. year -> 1996; isbn -> 1581138709 etc.
    my %article;  # (+)
    foreach (@entries) {
      $article{$_} = $entry->field($_);
    }

    # return article's key (Lee2000a, Forrest1996)
    $key = $entry->key;

    # insert %article into %bibliography with appropriate key
    $bibliography{$key} = \%article;
  }
  else {
    warn "Error parsing file: " . $entry->error;
  }
}
于 2012-12-07T16:37:15.203 回答