opengl - 如何在 OpenGL 中将基元渲染为线框？

Question

如何在 OpenGL 中将基元渲染为线框？

score 392 · Accepted Answer

glPolygonMode( GL_FRONT_AND_BACK, GL_LINE );

打开，

glPolygonMode( GL_FRONT_AND_BACK, GL_FILL );

恢复正常。

请注意，如果启用了纹理映射和照明等内容，它们仍将应用于线框线，这看起来很奇怪。

score 44 · Accepted Answer

来自http://cone3d.gamedev.net/cgi-bin/index.pl?page=tutorials/ogladv/tut5

// Turn on wireframe mode
glPolygonMode(GL_FRONT, GL_LINE);
glPolygonMode(GL_BACK, GL_LINE);

// Draw the box
DrawBox();

// Turn off wireframe mode
glPolygonMode(GL_FRONT, GL_FILL);
glPolygonMode(GL_BACK, GL_FILL);

score 29 · Accepted Answer

假设在 OpenGL 3 及更高版本中具有向前兼容的上下文，您可以glPolygonMode按照前面提到的方式使用，但请注意，现在不推荐使用粗细超过 1px 的线条。因此，虽然您可以将三角形绘制为线框，但它们需要非常薄。在 OpenGL ES 中，您可以使用GL_LINES相同的限制。

在 OpenGL 中，可以使用几何着色器来获取传入的三角形，分解它们并将它们发送为光栅化，作为模拟粗线的四边形（实际上是三角形对）。真的很简单，只是几何着色器因性能缩放而臭名昭著。

您可以做的，以及在 OpenGL ES 中也可以使用的方法是使用片段着色器。考虑将线框三角形的纹理应用于三角形。除了不需要纹理外，它可以通过程序生成。但是说够了，让我们来编码吧。片段着色器：

in vec3 v_barycentric; // barycentric coordinate inside the triangle
uniform float f_thickness; // thickness of the rendered lines

void main()
{
    float f_closest_edge = min(v_barycentric.x,
        min(v_barycentric.y, v_barycentric.z)); // see to which edge this pixel is the closest
    float f_width = fwidth(f_closest_edge); // calculate derivative (divide f_thickness by this to have the line width constant in screen-space)
    float f_alpha = smoothstep(f_thickness, f_thickness + f_width, f_closest_edge); // calculate alpha
    gl_FragColor = vec4(vec3(.0), f_alpha);
}

和顶点着色器：

in vec4 v_pos; // position of the vertices
in vec3 v_bc; // barycentric coordinate inside the triangle

out vec3 v_barycentric; // barycentric coordinate inside the triangle

uniform mat4 t_mvp; // modeview-projection matrix

void main()
{
    gl_Position = t_mvp * v_pos;
    v_barycentric = v_bc; // just pass it on
}

在这里，重心坐标很简单(1, 0, 0)，对于三个三角形顶点（顺序并不重要，这使得打包成三角形条带可能更容易）。(0, 1, 0)(0, 0, 1)

这种方法的明显缺点是它会吃掉一些纹理坐标并且你需要修改你的顶点数组。可以用一个非常简单的几何着色器来解决，但我仍然怀疑它会比仅仅向 GPU 提供更多数据要慢。

score 5 · Accepted Answer

如果您使用的是固定管道 (OpenGL < 3.3) 或兼容性配置文件，您可以使用

//Turn on wireframe mode
glPolygonMode(GL_FRONT_AND_BACK, GL_LINE);

//Draw the scene with polygons as lines (wireframe)
renderScene();

//Turn off wireframe mode
glPolygonMode(GL_FRONT_AND_BACK, GL_FILL);

在这种情况下，您可以通过调用glLineWidth来更改线宽

否则，您需要在您的绘图方法（glDrawElements、glDrawArrays 等）中更改多边形模式，并且您可能会得到一些粗略的结果，因为您的顶点数据用于三角形并且您正在输出线。为获得最佳结果，请考虑使用几何着色器或为线框创建新数据。

score 4 · Accepted Answer

在现代 OpenGL（OpenGL 3.2 及更高版本）中，您可以为此使用几何着色器：

#version 330

layout (triangles) in;
layout (line_strip /*for lines, use "points" for points*/, max_vertices=3) out;

in vec2 texcoords_pass[]; //Texcoords from Vertex Shader
in vec3 normals_pass[]; //Normals from Vertex Shader

out vec3 normals; //Normals for Fragment Shader
out vec2 texcoords; //Texcoords for Fragment Shader

void main(void)
{
    int i;
    for (i = 0; i < gl_in.length(); i++)
    {
        texcoords=texcoords_pass[i]; //Pass through
        normals=normals_pass[i]; //Pass through
        gl_Position = gl_in[i].gl_Position; //Pass through
        EmitVertex();
    }
    EndPrimitive();
}

注意事项：

对于点，更改layout (line_strip, max_vertices=3) out;为layout (points, max_vertices=3) out;
阅读有关几何着色器的更多信息

score 2 · Accepted Answer

最简单的方法是将基元绘制为GL_LINE_STRIP.

glBegin(GL_LINE_STRIP);
/* Draw vertices here */
glEnd();

score 1 · Accepted Answer

使用这个函数： void glPolygonMode( GLenum face, GLenum mode);

face ：指定该模式适用的多边形。可以是多边形正面的 GL_FRONT 和背面的 GL_BACK 和两者的 GL_FRONT_AND_BACK 。

mode ：定义了三种模式，可以在 mode 中指定：

GL_POINT ：标记为边界边缘起点的多边形顶点被绘制为点。

GL_LINE ：多边形的边界边缘被绘制为线段。（你的目标）

GL_FILL ：填充多边形的内部。

PS：glPolygonMode 控制图形管道中用于光栅化的多边形的解释。

有关更多信息，请查看 khronos 组中的 OpenGL 参考页面： https ://www.khronos.org/registry/OpenGL-Refpages/gl4/html/glPolygonMode.xhtml

score 1 · Accepted Answer

您可以像这样使用 glut 库：

对于一个球体：
```
glutWireSphere(radius,20,20);
```

对于气缸：

GLUquadric *quadratic = gluNewQuadric();
gluQuadricDrawStyle(quadratic,GLU_LINE);
gluCylinder(quadratic,1,1,1,12,1);

对于多维数据集：
```
glutWireCube(1.5);
```

score 0 · Accepted Answer

在非抗锯齿渲染目标上绘制抗锯齿线的一种简单而简单的方法是使用 1x4 纹理绘制 4 像素宽度的矩形，Alpha 通道值为 {0.,1.,1.,0.} , 并使用关闭 mip-mapping 的线性过滤。这将使线条厚 2 个像素，但您可以更改不同厚度的纹理。这比气压计算更快更容易。

score -1 · Accepted Answer

如果您正在处理的是OpenGL ES 2.0，您可以从

GL_LINE_STRIP, GL_LINE_LOOP, GL_LINES,画线，

GL_POINTS（如果您只需要绘制顶点），或者

GL_TRIANGLE_STRIP, GL_TRIANGLE_FAN, 和GL_TRIANGLES绘制实心三角形

作为你的第一个论点

glDrawElements(GLenum mode, GLsizei count, GLenum type, const GLvoid * indices)

或者

glDrawArrays(GLenum mode, GLint first, GLsizei count)来电。

opengl - 如何在 OpenGL 中将基元渲染为线框？

10 回答 10

Related

Reference