1

我正在使用 AS2 从外部站点将一些图像动态导入 SWF。当我从计算机加载图像时，它可以完美运行，但是当我尝试从外部服务器加载它们时，平滑不起作用。

我的代码：

    var imageLoad:MovieClipLoader = new MovieClipLoader();
    imageLoad.addListener({
        onLoadInit:function (target:MovieClip) {
            target._quality = "BEST";
            target._width = 160;
            target._yscale = target._xscale;
            if (target._height>105) {
                target._height = 105;
                target._xscale = target._yscale;
            }
            target.forceSmoothing = true;
        }
    });
imageLoad.loadClip(imageURL,imageMC);

我已经尝试了我可以在网上找到的所有解决方案，但没有人使用平滑...

有什么解决办法吗？

4

3 回答 3

1

不确定，但您遇到的问题似乎是跨域问题的症状。如果加载的 SWF 属性（在这种情况下是平滑处理）来自不同的域，您将无法修改它，除非跨域策略文件允许。

如果这不是问题，我记得从根本上绘制 bitmapData 总是成功的。如果结果是黑色图像，那么您很确定存在跨域问题。本文准确解释了 AS2 的技术：

http://www.kaourantin.net/2005/12/dynamically-loading-bitmaps-with.html

于 2009-09-03T22:51:31.553 回答
1

AS2……啊……回忆（更像是噩梦）。

试试我的'好老' BitmapLoader.as...我已经使用了很多年，但从未让我失望过...它写得并不漂亮，而且里面有一些双作用域设置器...但是我不在乎。它很旧，而且它完美地完成了它的工作（总是！）。它需要在构造函数中设置一个布尔值，将平滑设置为 true 或 false

import flash.display.BitmapData;

class BitmapLoader extends Object {

    private var mLoader : MovieClipLoader;
    private var scope : Object;
    private var _mc : MovieClip;
    private var _url : String;
    private var _func : Object;
    private var smooth : Boolean;

    public function BitmapLoader(smooth : Boolean) 
    {
        this.smooth = smooth;
        mLoader = new MovieClipLoader( );
        addListener( this );    
    }

    public function addListener(inListener : Object) : Void 
    {
        mLoader.addListener( inListener );
        scope = inListener;
    }

    public function removeListener(inListener : Object) : Void 
    {
        mLoader.removeListener( inListener );
    }

    private function onLoadInit(inTarget : MovieClip) : Void 
    {
        var bitmap : BitmapData = new BitmapData( inTarget._width, inTarget._height, true, 0x000000 );      
        bitmap.draw( inTarget );
        var parent : MovieClip = inTarget._parent;
        var img : MovieClip = parent.createEmptyMovieClip( "imageloader_smooth_mc", parent.getNextHighestDepth( ) );
        inTarget.unloadMovie( );
        inTarget.removeMovieClip( );
        delete inTarget;
        img.attachBitmap( bitmap, img.getNextHighestDepth( ), "never", true );
        scope[_func]( img );
    }

    private function onLoadError(errorCode : String, httpStatus : Number) : Void 
    {
        error( errorCode, httpStatus );
    }

    /**
     * loadBitmap( http://www.test.nl/img.jpg, movieclip, "dothis");
     */
    public function loadBitmap(url : String, mc : MovieClip, func : Object) : Void 
    {
        _url = url;
        _mc = mc;
        _func = func;
        var raw : MovieClip = _mc.createEmptyMovieClip( "imageloader_raw_mc", _mc.getNextHighestDepth( ) );
        mLoader.loadClip( _url, raw );
    }

    private function error(errorCode : String, httpStatus : Number) : Void 
    {
        var raw : MovieClip = _mc.createEmptyMovieClip( "imageloader_raw_mc", _mc.getNextHighestDepth( ) );
        mLoader.loadClip( "img/notfound.jpg", raw );
    };
}

你可以像这样使用这个类：

    var loader : BitmapLoader = new BitmapLoader( true );
loader.addListener( this );
loader.loadBitmap( "http://test.nl/example.jpg", this, "doneLoading" );

'true' 是平滑布尔值，addListener(this) 是为了防止范围问题（AS2-bleeh），而“doneLoading”是它在完成加载时调用的函数名。

希望这对你有用。

祝你好运！

于 2009-09-04T06:28:16.507 回答
1

如何在另一个带有缩放矩阵的 BitmapData 上绘制它？我听说它会比缩放位图本身更平滑......

下面的代码来自这里。

// source in this example is a DisplayObject
var temp:BitmapData = new BitmapData( sourceWidth, sourceHeight );
temp.draw( source );

var output:BitmapData = new BitmapData( outputWidth, outputHeight );

var matrix:Matrix = new Matrix();
matrix.scale( outputWidth / sourceWidth, outputHeight / sourceHeight );

output.draw( temp, matrix, null, null, null, true );
temp.dispose();
于 2009-09-09T06:16:14.097 回答