1

好的，简单解释一下我在做什么：我每天晚上使用 Windows Media Center (Windows 7) 录制 Jeopardy。然后我使用 Handbrake 将 .wtv 文件转换为 .mkv 文件，然后将它们传输到我的 NAS，以便稍后使用 Plex Media Server/Center 观看它们。我没有“手动”执行此操作，而是尝试使用批处理文件作为计划任务来自动化该过程。最初，我设置了一个脚本，以便我可以右键单击 > Send To > convert.bat，它会启动 Handbrake 的命令行界面并转换文件，将输出移动到我的 NAS，并删除原始文件（工作得很好）。

现在，我正在做的是将批处理脚本作为计划任务启动并循环通过我的“录制的电视”目录的内容并循环通过任何 .wtv 文件来转换/移动/删除它们。

问题在于 Windows Media Center 正确地用“！”命名 Jeopardy 文件。在其中（例如：Jeopardy!_KHQ_2012_12_04_21_12_12.wtv），这完全破坏了我的脚本。“发送到”批处理文件效果很好，但是当我遍历目录中的 *.wtv 文件时，它返回所有带有“！”的文件名 被剥离，这意味着我不能和他们一起蹲下。没有“！”的文件 顺利进行。

提前感谢任何可以让我指出正确方向的人！（如果您碰巧看到可以改进此脚本的任何其他领域，那也很好......）

这是我尝试使用的基本代码：

@echo off

setlocal ENABLEDELAYEDEXPANSION

SET count=0
SET getFolder=C:\Users\Public\Recorded TV\
SET ripFolder=C:\Rips\
SET putFolder=Z:\Videos\Recorded TV\

FOR %%F IN ("%getFolder%*.wtv") DO (
SET /A count=!count!+1

REM DETERMINE OUTPUT FILENAME
for /f "tokens=5,6,7,8,9,10 delims=\_" %%a in ("%%F") do (
    set show=%%a
    set station=%%b
    set year=%%c
    set month=%%d
    set day=%%e
    set hour=%%f

    REM GENERATE OUTPUT NAMING CONVENTION   
    set output=!show! s!year!e!month!!day! !hour!

)

REM PROCESS WITH HANDBRAKE CLI
"C:\Program Files\Handbrake\HandBrakeCLI.exe" -i "%%F" -t 1 -c 1 -o %ripFolder%!OUTPUT!.mkv  -f mkv --deinterlace="fast" --crop 58:60:2:2 --strict-anamorphic  -e x264 -q 20 --vfr  -a 1 -E faac -B 160 -6 dpl2 -R Auto -D 0 --gain=0 --audio-copy-mask none --audio-fallback ffac3 -x ref=1:weightp=1:subq=2:rc-lookahead=10:trellis=0:8x8dct=0 --verbose=1

REM MOVE CONVERTED FILE TO NAS
copy "%ripFolder%!OUTPUT!.mkv" "%putFolder%"

REM DELETE ORIGINAL
del "%%F"

REM DELETE LOCAL RIP
del "%ripFolder%!output!.mkv"
)

echo %count% files processed

pause

ENDLOCAL
4

1 回答 1

0

如您所见，感叹号在您逃脱之前已被剥离。
这是因为您在启用延迟扩展时扩展了 FOR 循环变量%%F，而感叹号会尝试扩展变量。

您需要在此处切换延迟扩展，因为使用延迟扩展时变量内容是安全的，但要获得值，您需要禁用模式。

@echo off
setlocal DisableDelayedExpansion
SET count=0

FOR %%F IN ("%getFolder%*.wtv") DO (
  set "orgFile=%%F"
  SET /A count+=1

  REM DETERMINE OUTPUT FILENAME
  for /f "tokens=5,6,7,8,9,10 delims=\_" %%a in ("%%F") do (
    set show=%%a
    set station=%%b
    set year=%%c
    set month=%%d
    set day=%%e
    set hour=%%f

    setlocal EnableDelayedExpansion
    REM GENERATE OUTPUT NAMING CONVENTION   
    set output=!show! s!year!e!month!!day! !hour!
  )
  REM PROCESS WITH HANDBRAKE CLI
  "C:\Program Files\Handbrake\HandBrakeCLI.exe" -i "%%F" -t 1 -c 1 -o %ripFolder%!OUTPUT!.mkv  -f mkv --deinterlace="fast" --crop 58:60:2:2 --strict-anamorphic  -e x264 -q 20 --vfr  -a 1 -E faac -B 160 -6 dpl2 -R Auto -D 0 --gain=0 --audio-copy-mask none --audio-fallback ffac3 -x ref=1:weightp=1:subq=2:rc-lookahead=10:trellis=0:8x8dct=0 --verbose=1

  REM MOVE CONVERTED FILE TO NAS
  copy "%ripFolder%!OUTPUT!.mkv" "%putFolder%"

  REM DELETE ORIGINAL
  del "!orgFile!"

  REM DELETE LOCAL RIP
  del "%ripFolder%!output!.mkv"
  endlocal
)
于 2012-12-05T06:51:51.480 回答