delphi - 如何重载父类中引入的虚函数？

Question

我有一个父类，其中包含一个重要的抽象过程，我在许多子类中重载了它，如下所示的示例代码：

TCParent = Class
private
public
 procedure SaveConfig; virtual; abstract;

end;

TCChild = Class(TCParent)
private
public
 procedure SaveConfig; override;
end;

现在我需要用另一个接受参数的 SaveConfig 过程（重载）这个过程，但我不想在父类中进行可能需要我去对所有其他子类进行更改的大更改。

有没有一种方法可以在这个特定的子类中重载 SaveConfig 而无需对父类和从它继承的其他子类进行重大更改？

Answer 1

您可以使用reintroduce添加新的重载方法。注意reintroduce; overload;子类中的顺序是必须的；如果你反转它们，代码将无法编译。

TCParent = Class
private
public
 procedure SaveConfig; virtual; abstract;
end;

TCChild = Class(TCParent)
private
public
 procedure SaveConfig; overload; override;
 procedure SaveConfig(const FileName: string); reintroduce; overload;
end;

（在 Delphi 7 中测试，所以应该在它和所有更高版本中工作。）

Answer 2

由于您不想对其他后代进行更改，我建议在父类中添加一个可选字段来保存参数，然后任何想要使用参数的后代都可以使用它们。这样，您不必更改覆盖的签名SaveConfig()。例如：

type
  TCParent = class
  protected
    SaveConfigParams: TStrings; // or whatever...
  public
    procedure SaveConfig; overload; virtual; abstract;
    procedure SaveConfig(Params: TStrings); overload;
  end;

procedure TCParent.SaveConfig(Params: TStrings);
begin
  SaveConfigParams := Params;
  try
    SaveConfig;
  finally
    SaveConfigParams := nil;
  end;
end;

.

type
  TCChild = class(TCParent)
  public
    procedure SaveConfig; override;
  end;

procedure TCChild.SaveConfig;
begin
  if SaveConfigParams <> nil then
  begin
    // do something that uses the parameters...
  end else begin
    // do something else...
  end;
end;

.

type
  TCChild2 = class(TCParent)
  public
    procedure SaveConfig; override;
  end;

procedure TCChild2.SaveConfig;
begin
  // do something, ignoring the SaveConfigParams...
end;