5

这可能有点傻，但我想知道这是否可能。

我有一个返回 sys_refcursor 的函数

CREATE OR REPLACE FUNCTION get_employee_details(p_emp_no IN EMP.EMPNO%TYPE)
   RETURN SYS_REFCURSOR
AS
   o_cursor   SYS_REFCURSOR;
BEGIN
   OPEN o_cursor FOR
      SELECT EMPNO,
             ENAME,
             JOB,
             MGR,
             HIREDATE,
             SAL,
             COMM,
             DEPTNO
        FROM emp
       WHERE EMPNO = p_emp_no;

   RETURN o_cursor;
 -- exception part
END;
/

我可以使用

select  get_employee_details('7369') from dual;

是否可以通过指定列名从上述函数中获取结果？例如，如果我想获得ename 或salary，如何在不使用plsql 块的情况下在sql 语句中指定？就像是

select  get_employee_details('7369') <specific column> from dual;
4

2 回答 2

12

为此，您可能需要查看PIPELINED函数。不过，您必须在 PL/SQL 级别声明显式类型。该部分将设置输出列名：

CREATE OR REPLACE TYPE my_rec AS OBJECT (
  c CHAR,
  n NUMBER(1)
);

CREATE OR REPLACE TYPE my_tbl AS TABLE OF my_rec;

现在，最大的优势是您不仅可以“重命名”列，还可以动态修改光标中的记录。例如：

CREATE OR REPLACE FUNCTION my_fct
RETURN my_tbl PIPELINED
AS
  -- dummy data - use your own cursor here
  CURSOR data IS
      SELECT 'a' as A, 1 AS B FROM DUAL UNION 
      SELECT 'b', 2 FROM DUAL UNION 
      SELECT 'c', 3 FROM DUAL UNION 
      SELECT 'd', 4 FROM DUAL;
BEGIN
  FOR the_row IN data
  LOOP 
      PIPE ROW(my_rec(the_row.a, the_row.b*2));
      --                                  ^^
      --                            Change data on the fly
  END LOOP;
END

用法：

SELECT * FROM TABLE(my_fct())
--            ^^^^^^^^^^^^^^^
--     Use this "virtual" table like any
--     other table. Supporting `WHERE`  clause
--     or any other SELECT clause you want

生产：

C   N
a   2
b   4
c   6
d   8
于 2014-09-19T17:04:41.260 回答
4

不，根本没有 a ref cursor，否则没有创建 SQL 类型以将返回值转换为，例如：http ://dbaspot.com/oracle-server/9308-select-ref-cursor.html ：

create or replace type myType as object (
a int,
b varchar2(10)
)
/

create or replace type myTable as table of myType;
/

create or replace function f1 return myTable as
l_data myTable := myTable();
begin
for i in 1 .. 5 loop
l_data.extend;
l_data(i) := myType(i, 'Row #'||i );
end loop;
return l_data;
end;
/

select * from TABLE ( cast( f1() as myTable ) );

---------- ----------
1 Row #1
2 Row #2
3 Row #3
4 Row #4
5 Row #5

从该线程的最后一篇文章中：

您已经知道的方式是唯一在选择语句中使用 REF CURSOR 的方式。

于 2012-12-03T19:29:06.450 回答