0

我在舞台中央放置了一个大球，“centerBall”。然后我添加了一堆较小的，给它们随机的大小和速度。这些将使用基本的运动代码移动并从墙上反弹。在每一帧上，在每个移动球和中心球之间进行基于距离的碰撞检查。如果发生碰撞，我会根据两个球之间的角度和最小距离计算出偏移弹簧目标。还有一个问题：一些较小的球绕过“centerBall”边界然后反弹。您可以在附图中看到。为什么会这样？这是代码：

import flash.display.Sprite;
import flash.events.Event;

public class Bubbles extends Sprite
{
    private var balls:Array;
    private var numBalls:Number = 10;
    private var centerBall:Ball;
    private var bounce:Number = -1;
    private var spring:Number = 0.2;

    public function Bubbles()
    {
        init();
    }

    private function init():void
    {
        balls = new Array();
        centerBall = new Ball(100, 0xcccccc);
        addChild(centerBall);
        centerBall.x = stage.stageWidth / 2;
        centerBall.y = stage.stageHeight / 2;

        for(var i:uint = 0; i < numBalls; i++)
        {
            var ball:Ball = new Ball(Math.random() * 40 + 5, Math.random() * 0xffffff);
            ball.x = Math.random() * stage.stageWidth;
            ball.y = Math.random() * stage.stageHeight;
            ball.vx = Math.random() * 6 - 3;
            ball.vy = Math.random() * 6 - 3;
            addChild(ball);
            balls.push(ball);
        }

        addEventListener(Event.ENTER_FRAME, onEnterFrame);          
    }

    private function onEnterFrame(event:Event):void
    {
        for(var i:uint = 0; i < numBalls; i++)
        {
            var ball:Ball = balls[i];
            move(ball);
            var dx:Number = ball.x - centerBall.x;
            var dy:Number = ball.y - centerBall.y;
            var dist:Number = Math.sqrt(dx * dx + dy * dy);
            var minDist:Number = ball.radius + centerBall.radius;
            if(dist < minDist)
            {
                var angle:Number = Math.atan2(dy, dx);
                var targetX:Number = centerBall.x + Math.cos(angle) * minDist;
                var targetY:Number = centerBall.y + Math.sin(angle) * minDist;
                ball.vx += (targetX - ball.x) * spring;
                ball.vy += (targetY - ball.y) * spring;
            }
        }
    }

    private function move(ball:Ball):void
    {
        ball.x += ball.vx;
        ball.y += ball.vy;
        if(ball.x + ball.radius > stage.stageWidth)
        {
            ball.x = stage.stageWidth - ball.radius;
            ball.vx *= bounce;
        }
        else if(ball.x - ball.radius < 0)
        {
            ball.x = ball.radius;
            ball.vx *= bounce;
        }
        if(ball.y + ball.radius > stage.stageHeight)
        {
            ball.y = stage.stageHeight - ball.radius;
            ball.vy *= bounce;
        }
        else if(ball.y - ball.radius < 0)
        {
            ball.y = ball.radius;
            ball.vy *= bounce;
        }
    }
}

点击这里查看图片

4

1 回答 1

0

您遇到的问题是您正在根据它们的帧而不是位置进行碰撞检测。

您需要检查它现在的位置和上一帧的位置，以便跟踪它的移动。这就是为什么它会穿过你的中心球，因为你检查当前帧是否有碰撞。

这是基于时间的圆碰撞检测的链接。

基于时间的碰撞

希望这可以帮助 ; )

于 2012-12-04T21:36:02.520 回答