3

请在下面找到传递数组、操作数组的代码片段，但我无法返回新版本的数组。

这是片段：

    proc    get_mroute_active { &multicast }   {
        upvar   ${&multicast} MULTICAST ;

                set group   -1 ;
                set src -1 ;
                                set     mcast_group_source_id   -1 ;
                                set     MULTICAST($mcast_group_source_id,id) $mcast_group_source_id ;
                                set     MULTICAST($mcast_group_source_id,mcast_group) $group ;
                                set     MULTICAST($mcast_group_source_id,mcast_source) $src ;

        puts    [array size MULTICAST] ;
    parray  MULTICAST ;
}


array set     multicast { } ;

get_mroute_active [array get multicast] ;
puts    [array size multicast] ;
parray multicast ;

代码的输出是：

3
MULTICAST(-1,id)           = -1
MULTICAST(-1,mcast_group)  = -1
MULTICAST(-1,mcast_source) = -1
0

您能帮我看看如何将“MULTICAST”变量分配给“multicast”吗？

4

1 回答 1

5

简短的回答是：你不能从一个过程中返回一个数组，因为数组不是值——它们是命名值的特殊命名集合。

有几种方法可以解决这个问题：

通常的方法是通过名称传递数组，并使被调用的过程就地修改数组。例如，代码

proc foo {arrayName} {
    upvar 1 $arrayName ary
    incr ary(one)
}
set x(one) 1
foo x
puts $x(one)

foo当过程修改调用者范围内指定数组中的特定值时，将打印“2” 。

注意调用者如何传递一个数组的名称，“x”，而不是“它的值”（因为你不能从一个数组中提取一个值；但见下文），然后被调用的过程通过它的使用upvar命令命名。

另一种方法是使用array get和array set命令从数组中提取键和值，并分别用键和值填充数组。例如：

set x(one) 1
set x(two) 2
array set another [array get x]
parray another

会打印

another(one) = 1
another(two) = 2

array get给定一个数组，该命令返回一个平面列表，其中的键和它们各自的值交错。通过这种方式，您可以从过程返回数组的内容array set，然后让调用者对这些内容执行任何操作，例如，使用命令在其范围内填充另一个数组（可能与传递给该过程的数组相同）首先）。

请注意，它array set具有合并语义：在使用源列表插入/替换其值之前，它不会清空目标数组。

第三种（可能是最好的）方法是使用字典，字典是键/值映射，就像数组一样，但它们本身就是值，因此它们可以作为其他值自由传递。这需要 Tcl 8.5 或更高版本（在 Tcl 8.4 中，您可以以包的形式使用此代码的反向移植dict。使用s 可以得到它：

proc foo d {
    dict set d one 2
    return $d
}
set x [dict create]
dict set x one 1
set y [foo $x]
puts $y

当过程修改原始字典然后返回它然后调用者将它分配给另一个变量时，它将打印“one 2”。

于 2012-12-02T00:36:26.150 回答