43

我在节点中有一个字符串，我想将字符串拆分为“？” 并返回数组中的最后一项。

例如，在下面的块中：

<a>
    <xsl:attribute name="href">
        /newpage.aspx?<xsl:value-of select="someNode"/>
    </xsl:attribute>
    Link text
</a>

我想拆分someNode价值。

编辑：这是我用来为我的 Asp.Net 页面加载 Xsl 的 VB.Net：

Dim xslDocPath As String = HttpContext.Current.Server.MapPath("~/App_Data/someXslt.xsl")
Dim myXsltSettings As New XsltSettings()
Dim myXMLResolver As New XmlUrlResolver()

myXsltSettings.EnableScript = True
myXsltSettings.EnableDocumentFunction = True

myXslDoc = New XslCompiledTransform(False)
myXslDoc.Load(xslDocPath, myXsltSettings, myXMLResolver)

Dim myStringBuilder As New StringBuilder()
Dim myXmlWriter As XmlWriter = Nothing

Dim myXmlWriterSettings As New XmlWriterSettings()
myXmlWriterSettings.ConformanceLevel = ConformanceLevel.Auto
myXmlWriterSettings.Indent = True
myXmlWriterSettings.OmitXmlDeclaration = True

myXmlWriter = XmlWriter.Create(myStringBuilder, myXmlWriterSettings)

myXslDoc.Transform(xmlDoc, argumentList, myXmlWriter)

Return myStringBuilder.ToString()

更新：这是在特定节点上拆分 XML 的示例

4

8 回答 8

51

使用递归方法：

<xsl:template name="output-tokens">
    <xsl:param name="list" /> 
    <xsl:variable name="newlist" select="concat(normalize-space($list), ' ')" /> 
    <xsl:variable name="first" select="substring-before($newlist, ' ')" /> 
    <xsl:variable name="remaining" select="substring-after($newlist, ' ')" /> 
    <id>
        <xsl:value-of select="$first" /> 
    </id>
    <xsl:if test="$remaining">
        <xsl:call-template name="output-tokens">
            <xsl:with-param name="list" select="$remaining" /> 
        </xsl:call-template>
    </xsl:if>
</xsl:template>
于 2008-09-26T18:04:00.030 回答
12

如果您可以使用 XSLT 2.0 或更高版本，您可以使用tokenize(string, separator)：

tokenize("XPath is fun", "\s+")
Result: ("XPath", "is", "fun")

请参阅w3schools XPath 函数参考。

默认情况下，.NET 不支持 XSLT 2.0，更不用说 XSLT 3.0。唯一已知的 .NET 2.0+ 处理器是带有IKVM的Saxon for .NET、Exselt、一个当前处于测试阶段的 .NET XSLT 3.0 处理器和XMLPrime XSLT 2.0 处理器。

于 2008-09-25T22:14:35.080 回答
8

我最终使用了该substring-after()功能。这对我有用：

<a>
    <xsl:attribute name="href">
        /newpage.aspx?<xsl:value-of select="substring-after(someNode, '?')"/>
    </xsl:attribute>
    Link text
</a>

即使将 XSLT 的版本设置为 2.0 后，'tokenize()' is an unknown XSLT function.尝试使用tokenize().

于 2008-09-25T23:24:49.530 回答
6

添加另一种可能性，如果您的模板引擎支持EXSLT，那么您可以使用tokenize()。

例如：

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:str="http://exslt.org/strings"
                extension-element-prefixes="str">

...
  <a>
    <xsl:attribute name="href">
      <xsl:text>/newpage.aspx?</xsl:text>
      <xsl:value-of select="str:tokenize(someNode)[2]"/>
    </xsl:attribute>              
  </a>
...
</xsl:stylesheet>
于 2010-05-19T16:06:49.070 回答
3

不幸的是，.NET 不支持 XSLT 2.0。我很确定它支持 EXSLT，它有一个split()函数。Microsoft 有一个关于其 EXSLT 实施 的旧页面。

于 2008-09-26T18:44:02.743 回答
2

string-before您可以使用和string-after函数编写模板并在其中使用它。我为此写了一篇博客。

最后想出了一个 xslt 模板，它将分隔的字符串拆分为子字符串。我不声称它是最聪明的脚本，但肯定能解决我的问题。

样式表：

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<xsl:for-each select="Paths/Item">
<xsl:call-template name="SplitText">
<xsl:with-param name="inputString" select="Path"/>
<xsl:with-param name="delimiter" select="Delimiter"/>
</xsl:call-template>
<br/>
</xsl:for-each>
</xsl:template>
<xsl:template name="SplitText">
<xsl:param name="inputString"/>
<xsl:param name="delimiter"/>
<xsl:choose>
<xsl:when test="contains($inputString, $delimiter)">
<xsl:value-of select="substring-before($inputString,$delimiter)"/>
<xsl:text disable-output-escaping = "no"> </xsl:text>
<xsl:call-template name="SplitText">
<xsl:with-param name="inputString" select="substring-after($inputString,$delimiter)"/>
<xsl:with-param name="delimiter" select="$delimiter"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:choose>
<xsl:when test="$inputString = ''">
<xsl:text></xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$inputString"/>
<xsl:text> </xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>

XML 文件（待转换）：

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet type="text/xsl" href="textSpliter.xslt"?>
<Paths>
  <Item>
    <Path>C:\ProgramFiles\SomeWierdSoftware</Path>
    <Delimiter>\</Delimiter>
  </Item>
</Paths>
于 2011-05-28T08:18:16.187 回答
1

XSLT 1.0 本身没有 split 函数，但您可以通过 substring-before 和 substring-after 函数实现您想要做的事情。

或者，如果您使用的是 Microsoft XSLT 引擎，则可以使用内联 C#。

于 2008-09-25T22:18:09.627 回答
1

仅作记录，如果您使用 1.0 执行此操作，并且您确实需要拆分/标记，则需要xslt extensions。

于 2008-09-26T08:04:59.233 回答