6

我有一个数据结构：

data = array of integer;

我已经从一个

source = array of byte;

和

data[x] := Source[offset] or (Source[offset + 1] shl 8) or
    (Source[offset + 2] shl 16) or (Source[offset + 3] shl 24);

处理完这些块后，我必须将它们带回“字节”......

任何的想法？

4

5 回答 5

7

你的意思是这样吗？

var
  i: integer;
  b1, b2, b3, b4: byte;
begin
  b1 := byte(i);
  b2 := byte(i shr 8);
  b3 := byte(i shr 16);
  b4 := byte(i shr 24);

试一下，例如，

procedure TForm1.FormCreate(Sender: TObject);
var
  i: integer;
  b1, b2, b3, b4: byte;
begin
  i := $AABBCCDD;
  b1 := byte(i);
  b2 := byte(i shr 8);
  b3 := byte(i shr 16);
  b4 := byte(i shr 24);
  ShowMessage(IntToHex(b1, 2));
  ShowMessage(IntToHex(b2, 2));
  ShowMessage(IntToHex(b3, 2));
  ShowMessage(IntToHex(b4, 2));
end;
于 2012-11-29T20:34:28.990 回答
7

您可以使用 Move 在单行中执行此操作。

Move(source[0], dest[0], Length(source)*SizeOf(source[0]));

如果您需要执行网络/主机字节顺序转换，则可以在Move.

在相反的方向上，您将全部反向进行。

如果您没有字节顺序问题，那么您实际上可能根本不需要转换为字节数组。您可以按原样使用整数数组。请记住，在没有字节顺序问题的情况下，字节数组和整数数组的内存布局是相同的（这就是您能够使用 blit 的原因Move）。

于 2012-11-29T20:46:02.277 回答
7

嗯...我看到一个使用 Move 的答案和一个使用 shift 的答案，但是简单的演员阵容呢？：

var
  I: Integer;
  B: array[0..3] of Byte;
begin
  // from bytes to integer:
  I := PInteger(@B)^;
  // from integer to bytes:
  PInteger(@B)^ := I;

或者使用您的数组：

data[i] := PInteger(@source[offset])^;

反之亦然：

// get low byte
source[offset] := PByte(@data[i])^; // or := PByte(@data[i])[0];
// get second byte
secondByte := PByte(@data[i])[1]; // or := (PByte(@data[i]) + 1)^;

或者

PInteger(@source[offset])^ := data[i];

如您所见，您可以通过转换为指针获得很长的路要走。这实际上并不需要指针，编译器足够聪明，可以直接访问这些项目。

于 2012-11-29T21:08:51.280 回答
0

正如所评论的，您无需移动数据即可以字节和整数的形式访问它。

您的原始字节数组可以通过类型转换作为整数数组访问。

type
  TArrayInteger = array of Integer;
...
for i := 0 to Pred(Length(source)) div SizeOf(Integer) do
  WriteLn(TArrayInteger(source)[i]);

我经常将这些类型转换隐藏在一个类中。在 XE3 中，可以为简单类型（如字符串、字节、整数等）声明类助手。例如，请参阅 TStringHelper。简单类型的数组也是如此。

下面是一个使用记录助手的例子：

type
  TArrayByte = array of Byte;
  TArrayInteger = array of Integer;

  TArrayByteHelper = record helper for TArrayByte
  private
    function GetInteger(index : Integer) : Integer;
    procedure SetInteger(index : Integer; value : Integer);
  public
    property AsInteger[index : Integer] : Integer read GetInteger write SetInteger;
  end;

function TArrayByteHelper.GetInteger(index: Integer): Integer;
begin
  Result := TArrayInteger(Self)[index];
end;

procedure TArrayByteHelper.SetInteger(index: Integer; value: Integer);
begin
  TArrayInteger(Self)[index] := value;
end;

像这样使用它：

Var
  source : TArrayByte;
  i : Integer;
begin
  SetLength(source,8);
  for i := 0 to 7 do
    source[i] := i;
  for i := 0 to 1 do
    WriteLn(Format('%8.8X',[source.AsInteger[i]]));
  ReadLn;
end.
于 2012-11-29T22:15:13.047 回答
0

要将其构建为函数：

Type TBytes = array of byte;

function InttoBytes(const int: Integer): TBytes;
begin
  result[0]:= int and $FF;
  result[1]:= (int shr 8) and $FF;
  result[2]:= (int shr 16) and $FF;
end;
于 2020-12-02T08:50:30.087 回答