delphi - 如何从某个 IMAP 邮箱中获取所有电子邮件的正文？

Question

如何从 Delphi 中的某个 IMAP 邮箱获取所有电子邮件的正文？例如，来自INBOX邮箱？

Answer 1

有多种方法可以从所选邮箱中检索所有邮件的所有正文。我使用了一个，您可以在其中逐一迭代邮箱和邮箱中的Retrieve每条消息。这种方式允许您修改代码，以便您能够在需要时中断循环，或者例如替换Retrieve不会RetrievePeek像第一次提到的那样在服务器上将消息标记为已读。当从服务器检索消息时，它的所有部分都被迭代，当它是文本部分时，它的正文被附加到一个局部S变量中。在迭代之后，S变量被添加到输出BodyTexts字符串列表中。所以，结果你会得到字符串列表集合，其中每个项目都来自连接的消息'

uses
  IdIMAP4, IdSSLOpenSSL, IdText, IdMessage, IdExplicitTLSClientServerBase;

procedure GetGmailBodyTextParts(const UserName, Password: string;
  BodyTexts: TStrings);
var
  S: string;
  MsgIndex: Integer;
  MsgObject: TIdMessage;
  PartIndex: Integer;
  IMAPClient: TIdIMAP4;
  OpenSSLHandler: TIdSSLIOHandlerSocketOpenSSL;
begin
  BodyTexts.Clear;
  IMAPClient := TIdIMAP4.Create(nil);
  try
    OpenSSLHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil);
    try
      OpenSSLHandler.SSLOptions.Method := sslvSSLv3;
      IMAPClient.IOHandler := OpenSSLHandler;
      IMAPClient.Host := 'imap.gmail.com';
      IMAPClient.Port := 993;
      IMAPClient.UseTLS := utUseImplicitTLS;
      IMAPClient.Username := UserName;
      IMAPClient.Password := Password;
      IMAPClient.Connect;
      try
        if IMAPClient.SelectMailBox('INBOX') then
        begin
          BodyTexts.BeginUpdate;
          try
            for MsgIndex := 1 to IMAPClient.MailBox.TotalMsgs do
            begin
              MsgObject := TIdMessage.Create(nil);
              try
                S := '';
                IMAPClient.Retrieve(MsgIndex, MsgObject);
                MsgObject.MessageParts.CountParts;
                if MsgObject.MessageParts.TextPartCount > 0 then
                begin
                  for PartIndex := 0 to MsgObject.MessageParts.Count - 1 do
                    if MsgObject.MessageParts[PartIndex] is TIdText then
                      S := S + TIdText(MsgObject.MessageParts[PartIndex]).Body.Text;
                  BodyTexts.Add(S);
                end
                else
                  BodyTexts.Add(MsgObject.Body.Text);
              finally
                MsgObject.Free;
              end;
            end;
          finally
            BodyTexts.EndUpdate;
          end;
        end;
      finally
        IMAPClient.Disconnect;
      end;
    finally
      OpenSSLHandler.Free;
    end;
  finally
    IMAPClient.Free;
  end;
end;

此代码需要 OpenSSL，因此不要忘记将libeay32.dll和ssleay32.dll库放在项目可见的路径中；您可以为 Indy 下载不同版本和平台的 OpenSSL 库from here。