xslt-2.0 - XSLT 用多个标签包装文本

Question

我有这个跨度元素与一类autbib-pc-bold-italic

<span class="autbib-pc-bold-italic">autbib</span>

我想基于 @class 属性值创建元素标签：

我的输出应该是：

<autbib><pc><bold><italic>autbib</italic></bold></pc></autbib>

这是我的 xsl 模板：

<xsl:template match="span[contains(@class,'autbib')]">
    <xsl:call-template name="pbib.loop">
        <xsl:with-param name="count" select="count(tokenize(@class, '-'))"/>
        <xsl:with-param name="class" select="tokenize(@class, '-')"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="pbib.loop">
    <xsl:param name="index" select="1" />
    <xsl:param name="count" select="count(tokenize(@class, '-')) + 1"/>
    <xsl:param name="class" select="tokenize(@class, '-')"/>
    <xsl:element name="{$class[1]}">
       <xsl:if test="not($index = $count)">
            <xsl:element name="{$class[$index]}">
                <xsl:apply-templates/>
            </xsl:element>
       </xsl:if>
    </xsl:element>

    <xsl:if test="not($index = $count)">
        <xsl:call-template name="pbib.loop">
            <xsl:with-param name="index" select="$index + 1" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

并且有这个错误的输出：

<autbib>
    <pc>autbib</pc>
    <bold>autbib</bold>
    <italic>autbib</italic>
</autbib>

我需要有这个输出：

<autbib>
    <pc>
        <bold>
            <italic>autbib</italic>
        </bold>
    </pc>
</autbib>

我的问题是我不确定应该放置在哪里，xsl:apply-template以便标签相互包裹。

Answer 1

这是我的建议：

<xsl:stylesheet 
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:output indent="yes"/>

<xsl:template match="span[contains(@class,'autbib')]">
  <xsl:param name="classes" select="tokenize(@class, '-')"/>
  <xsl:choose>
    <xsl:when test="not($classes[1])">
      <xsl:apply-templates/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:element name="{$classes[1]}">
        <xsl:apply-templates select=".">
          <xsl:with-param name="classes" select="$classes[position() gt 1]"/>
        </xsl:apply-templates>
      </xsl:element>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>

使用 Saxon 9.4 转换输入

<span class="autbib-pc-bold-italic">autbib</span>

进入结果

<autbib>
   <pc>
      <bold>
         <italic>autbib</italic>
      </bold>
   </pc>
</autbib>