1

我试图在 XSLT 中获取自定义生成的字符串序列的唯一值。手头的问题很不寻常，因为我必须先在 '.' 上拆分一个字符串。最后一点，这工作正常，但使用 XSLT 2.0 distinct-values 获取唯一值不是。

给定一些输入

<TreeNumberList>
  <TreeNumber>A01.001.001</TreeNumber>  
  <TreeNumber>A01.001.002</TreeNumber>  
  <TreeNumber>A01.001.003</TreeNumber>
  <TreeNumber>A01.002.111</TreeNumber>
</TreeNumberList>

所需的输出将是一个可迭代的序列

A01.001, A01.002

到目前为止，我有以下功能

<xsl:function name="func:strip-last">
    <xsl:param name="str"></xsl:param>
    <xsl:value-of select="substring($str, 1, string-length($str) - 1)"></xsl:value-of>
</xsl:function>

<xsl:function name="func:parent-of">
    <xsl:param name="nodes"></xsl:param>
    <xsl:variable name="output">
    <xsl:for-each select="$nodes">
        <xsl:variable name="parent">
            <xsl:for-each select="tokenize(., '\.')">
                <xsl:if test="position() != last()">
                    <xsl:value-of select="."></xsl:value-of>
                    <xsl:text>.</xsl:text>
                </xsl:if>
            </xsl:for-each>
        </xsl:variable>
        <tmp><xsl:value-of select="func:strip-last($parent))"></xsl:value-of></tmp>
    </xsl:for-each>    
    </xsl:variable>
    <xsl:sequence select="distinct-values($output/*)"></xsl:sequence>
</xsl:function>

但这不会返回一组不同的元素，而是所有涉及的元素的序列。最终的代码会有点做作，因为 TreeNumbers 本身不是唯一的，但通过键查找检索到的某个名称将是唯一的。（对于那些识别标记的人，它是 MeSH XML 的一部分）

我还尝试使用键索引或分组方式来实现唯一性，但这些与文档片段的配合并不好。

4

2 回答 2

2

以下表达式将一组不同的值作为字符串序列给出：

distinct-values(TreeNumber/replace(., '\..*$', ''))
于 2012-11-26T22:26:40.447 回答
1

你必须有功能吗？你能创建一个具有序列的变量吗？

例子...

XML 输入

<TreeNumberList>
    <TreeNumber>A01.001.001</TreeNumber>  
    <TreeNumber>A01.001.002</TreeNumber>  
    <TreeNumber>A01.001.003</TreeNumber>
    <TreeNumber>A01.002.111</TreeNumber>
</TreeNumberList>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="vAllTreeNumbers">
        <xsl:for-each select="/*/TreeNumber">
            <xsl:analyze-string select="." regex="(.*)\.[^.]*$">
                <xsl:matching-substring>
                    <xsl:value-of select="concat(regex-group(1),' ')"/>
                </xsl:matching-substring>
            </xsl:analyze-string>
        </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="vUniqueTreeNumbers" select="distinct-values(tokenize(normalize-space($vAllTreeNumbers),' '))"/>

    <xsl:template match="/">
        <results>
            <!--This demonstrates that each value is part of a sequence.-->
            <xsl:for-each select="$vUniqueTreeNumbers">
                <item>
                    <xsl:value-of select="."/>
                </item>
            </xsl:for-each>
        </results>
    </xsl:template>

</xsl:stylesheet>

XML 输出（只是为了演示顺序）

<results>
   <item>A01.001</item>
   <item>A01.002</item>
</results>

这是另一个返回相同结果的选项...

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:local="local"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="#all">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:function name="local:getUniqueTreeNumbers">
        <xsl:param name="pNodes"/>
        <xsl:variable name="vAllTreeNumbers">
            <xsl:for-each select="$pNodes">
                <xsl:analyze-string select="." regex="(.*)\.[^.]*$">
                    <xsl:matching-substring>
                        <xsl:value-of select="concat(regex-group(1),' ')"/>
                    </xsl:matching-substring>
                </xsl:analyze-string>
            </xsl:for-each>
        </xsl:variable>
        <xsl:sequence select="distinct-values(tokenize(normalize-space($vAllTreeNumbers),' '))"></xsl:sequence>
    </xsl:function>

    <xsl:template match="/">
        <results>
            <!--This demonstrates that each value is part of an iterable sequence.-->
            <xsl:for-each select="local:getUniqueTreeNumbers(*/TreeNumber)">
                <item>
                    <xsl:value-of select="."/>
                </item>
            </xsl:for-each>         
        </results>
    </xsl:template>

</xsl:stylesheet>
于 2012-11-26T21:50:12.803 回答