10

我在 PL/SQL 中有一个函数，它检查一个特定的是否emp_id存在，它是：

CREATE OR REPLACE FUNCTION checkEmpNo(eno numeric)
RETURN boolean IS
    emp_number number;
BEGIN
    SELECT emp_id INTO emp_number
    FROM emp;
    IF eno=emp_number
    THEN
        return true;
    ELSE
        return false;
    END IF;
END checkEmpNo;

该函数编译成功，但是当我尝试将其运行为：

DECLARE
    exist boolean;
BEGIN
    exist=checkEmpNo(1);
    dbms_output.put_line(exist);
END;

它返回错误：

ORA-06550: line 5, column 1:
PLS-00306: wrong number or types of arguments in call to 'PUT_LINE'
ORA-06550: line 5, column 1:
PL/SQL: Statement ignored

3. BEGIN
4. exist:=checkEmpNo(1);
5. dbms_output.put_line(exist);
6. END;

编辑：

我也试过这个：

DECLARE
    exist boolean:=true;
BEGIN
    if(exist=checkEmpNo(1))
    then
        dbms_output.put_line('true');
    else
        dbms_output.put_line('false');
    end if;
END;

它返回错误：ORA-01422: exact fetch returns more than requested number of rows

4

2 回答 2

15

dbms_output.put_line没有重载以接受布尔参数。你可以做类似的事情

dbms_output.put_line( case when exist = true 
                           then 'true'
                           else 'false'
                        end );

将布尔值转换为字符串，然后您可以将其传递给dbms_output.

ORA-01422 错误是一个完全独立的问题。该函数checkEmpNo包括SELECT INTO语句

SELECT emp_id 
  INTO emp_number
  FROM emp;

SELECT INTO如果查询返回除 1 行以外的任何内容，A将生成错误。在这种情况下，如果表中有多行，emp则会出现错误。我的猜测是你会希望你的函数做类似的事情

CREATE OR REPLACE FUNCTION checkEmpNo(p_eno number)
  RETURN boolean 
IS
  l_count number;
BEGIN
  SELECT count(*)
    INTO l_count
    FROM emp
   WHERE emp_id = p_eno;

  IF( l_count = 0 )
  THEN
    RETURN false;
  ELSE
    RETURN true;
  END IF;
END checkEmpNo;
于 2012-11-26T07:00:23.093 回答
9

Alternatively you can use the Oracle function diutil.bool_to_int to convert a boolean value to an integer: True -> 1, False -> 0.

dbms_output.put_line(diutil.bool_to_int(p_your_boolean));
于 2012-11-26T07:20:06.047 回答