6

我正在使用 Delphi7（非 unicode VCL），我需要在 TFileStream 中存储大量 WideStrings。我不能使用 TStringStream 因为（宽）字符串与二进制数据混合，该格式预计可以加速加载和写入数据......但是我相信我当前加载/写入字符串的方式可能是我的代码的瓶颈......

目前我正在写一个字符串的长度，然后逐个字符地写它......在加载时，首先我正在加载长度，然后逐个字符地加载字符......

那么，将 WideString 保存和加载到 TFileStream 的最快方法是什么？

提前致谢

4

4 回答 4

6

与其一次读取和写入一个字符，不如一次读取和写入它们：

procedure WriteWideString(const ws: WideString; stream: TStream);
var
  nChars: LongInt;
begin
  nChars := Length(ws);
  stream.WriteBuffer(nChars, SizeOf(nChars);
  if nChars > 0 then
    stream.WriteBuffer(ws[1], nChars * SizeOf(ws[1]));
end;

function ReadWideString(stream: TStream): WideString;
var
  nChars: LongInt;
begin
  stream.ReadBuffer(nChars, SizeOf(nChars));
  SetLength(Result, nChars);
  if nChars > 0 then
    stream.ReadBuffer(Result[1], nChars * SizeOf(Result[1]));
end;

现在，从技术上讲，由于WideString是 Windows BSTR，它可以包含奇数个字节。该Length函数读取字节数并除以 2，因此上面的代码有可能（尽管不太可能）会切断最后一个字节。您可以改用此代码：

procedure WriteWideString(const ws: WideString; stream: TStream);
var
  nBytes: LongInt;
begin
  nBytes := SysStringByteLen(Pointer(ws));
  stream.WriteBuffer(nBytes, SizeOf(nBytes));
  if nBytes > 0 then
    stream.WriteBuffer(Pointer(ws)^, nBytes);
end;

function ReadWideString(stream: TStream): WideString;
var
  nBytes: LongInt;
  buffer: PAnsiChar;
begin
  stream.ReadBuffer(nBytes, SizeOf(nBytes));
  if nBytes > 0 then begin
    GetMem(buffer, nBytes);
    try
      stream.ReadBuffer(buffer^, nBytes);
      Result := SysAllocStringByteLen(buffer, nBytes)
    finally
      FreeMem(buffer);
    end;
  end else
    Result := '';
end;

受Mghie 回答的启发，将我的ReadandWrite电话替换为ReadBufferand WriteBuffer。如果后者无法读取或写入请求的字节数，后者将引发异常。

于 2009-08-30T15:38:10.580 回答
6

宽字符串没有什么特别之处，要尽可能快地读写它们，你需要一口气尽可能多地读写：

procedure TForm1.Button1Click(Sender: TObject);
var
  Str: TStream;
  W, W2: WideString;
  L: integer;
begin
  W := 'foo bar baz';

  Str := TFileStream.Create('test.bin', fmCreate);
  try
    // write WideString
    L := Length(W);
    Str.WriteBuffer(L, SizeOf(integer));
    if L > 0 then
      Str.WriteBuffer(W[1], L * SizeOf(WideChar));

    Str.Seek(0, soFromBeginning);
    // read back WideString
    Str.ReadBuffer(L, SizeOf(integer));
    if L > 0 then begin
      SetLength(W2, L);
      Str.ReadBuffer(W2[1], L * SizeOf(WideChar));
    end else
      W2 := '';
    Assert(W = W2);
  finally
    Str.Free;
  end;
end;
于 2009-08-30T15:39:19.750 回答
2

WideStrings 包含 WideChar 的“字符串”，每个使用 2 个字节。如果您想将 UTF-16（WideStrings 内部使用）字符串存储在一个文件中，并且能够在记事本等其他程序中使用该文件，您需要先写入一个字节顺序标记：#$FEFF.

如果你知道这一点，写作可以是这样的：

Stream1.Write(WideString1[1],Length(WideString)*2); //2=SizeOf(WideChar)

阅读可以是这样的：

Stream1.Read(WideChar1,2);//assert returned 2 and WideChar1=#$FEFF
SetLength(WideString1,(Stream1.Size div 2)-1);
Stream1.Read(WideString1[1],(Stream1.Size div 2)-1);
于 2009-08-30T16:10:49.610 回答
1

您还可以使用 TFastFileStream 读取数据或字符串，我将单元粘贴在http://pastebin.com/m6ecdc8c2和下面的示例：

program Project36;

{$APPTYPE CONSOLE}

uses
  SysUtils, Classes,
  FastStream in 'FastStream.pas';

const
  WideNull: WideChar = #0;

procedure WriteWideStringToStream(Stream: TFileStream; var Data: WideString);
var
  len: Word;
begin
  len := Length(Data);
  // Write WideString length
  Stream.Write(len, SizeOf(len));
  if (len > 0) then
  begin
    // Write WideString
    Stream.Write(Data[1], len * SizeOf(WideChar));
  end;
  // Write null termination
  Stream.Write(WideNull, SizeOf(WideNull));
end;

procedure CreateTestFile;
var
  Stream: TFileStream;
  MyString: WideString;
begin
  Stream := TFileStream.Create('test.bin', fmCreate);
  try
    MyString := 'Hello World!';
    WriteWideStringToStream(Stream, MyString);

    MyString := 'Speed is Delphi!';
    WriteWideStringToStream(Stream, MyString);
  finally
    Stream.Free;
  end;
end;

function ReadWideStringFromStream(Stream: TFastFileStream): WideString;
var
  len: Word;
begin
  // Read length of WideString
  Stream.Read(len, SizeOf(len));
  // Read WideString
  Result := PWideChar(Cardinal(Stream.Memory) + Stream.Position);
  // Update position and skip null termination
  Stream.Position := Stream.Position + (len * SizeOf(WideChar)) + SizeOf(WideNull);
end;

procedure ReadTestFile;
var
  Stream: TFastFileStream;

  my_wide_string: WideString;
begin
  Stream := TFastFileStream.Create('test.bin');
  try
    Stream.Position := 0;
    // Read WideString
    my_wide_string := ReadWideStringFromStream(Stream);
    WriteLn(my_wide_string);
    // Read another WideString
    my_wide_string := ReadWideStringFromStream(Stream);
    WriteLn(my_wide_string);
  finally
    Stream.Free;
  end;
end;

begin
  CreateTestFile;
  ReadTestFile;
  ReadLn;
end.
于 2009-08-30T18:52:51.827 回答