11

我正在尝试编写一个具有严格FP16限制的紧凑而简单的噪声函数。到目前为止，这是我得出的结论，但我认为在操作的某个地方，对于fract或sin来说，数字太小了，因为在 GPU 中我必须写这个，因为这些都在FP16限制之内。关于我做错了什么的任何想法？顺便说一句，我不能使用时间变量，也不能采样噪声纹理。我需要正确的功能必须紧凑、小巧且自给自足，并产生简单的颗粒状噪声效果。注意：下一个算法在任何桌面 GPU 卡上都可以正常工作，但在“ MALI 400 MP ”GPU 上完全失败，因为这个算法对浮点值有 FP16 限制。

vec3 noise(vec3 color)
{
    float variation = length(color);
    float dot_product = dot(variation, -0.577350269);
    float sin_result = sin(dot_product) * 1.19245;
    float random = fract(sin_result);
    return color + vec3(random);
}

如果有人可以为GLSL-ES推荐任何其他随机函数，但严格限制FP16，那也很好。我知道其他随机实现，例如单纯形噪声，但这些对于我需要做的事情来说太大而且太慢了。所以Perlin和Simplex噪声算法不是一个选择。

4

3 回答 3

1

这些是我使用的，但我不知道是否适用于 FP16 限制：

// source: http://byteblacksmith.com/improvements-to-the-canonical-one-liner-glsl-rand-for-opengl-es-2-0/
highp float rand(vec2 co)
{
      highp float a = 12.9898;
      highp float b = 78.233;
      highp float c = 43758.5453;
      highp float dt= dot(co.xy ,vec2(a,b));
      highp float sn= mod(dt,3.14);
      return fract(sin(sn) * c);
}

 float rand2(vec2 co)
{
      return fract(sin(dot(co.xy,vec2(12.9898,78.233))) * 43758.5453);
}

我没有创造这些。原作者的链接在上面。我实际上使用了 rand2 并且没有在那个博客上提到这个问题。要制作灰度噪音，请执行以下操作：

float randColor = rand(v_position);
gl_FragColor = vec4(randColor);

要制作全彩色噪点，需要 3 倍的时间，你会这样做：

gl_FragColor = vec4(rand(v_position), rand(v_position), rand(v_position), 1.0);

要为您正在绘制的任何内容添加噪音，您可以：

float randColor = rand(v_position) * .1;  // to add 10% noise
gl_FragColor = vec4(gl_FragColor.r + randColor, gl_FragColor.g + randColor, gl_FragColor.b + randColor, 1.0);

顺便说一句，这很慢。在 iPhone5 上，这可以正常工作，没有明显的减速。但在 4S 上，它的 fps 下降到 30。如果我去掉添加的噪音，它会提高到 60。所以要小心。

于 2014-05-29T21:37:48.590 回答
0

散列函数就足够了吗？Pearson 散列在过去是为 8 位寄存器设计的，并且非常简单：您硬编码一个 256 字节的查找表（或者，如果这是不可能的，则可以使用某种简单但非线性的排列），我们'将调用 T。对于输入的每个字节，您将它与到目前为止的散列进行异或，然后查找该值以获得新的散列。

在您的情况下，让 R、G 和 B 成为您的输入字节。那么哈希可能是

  • R噪声 = T[R^T[G^T[B]]]
  • 噪声 = T[G^T[B^T[R]]]
  • B噪声 = T[B^T[R^T[G]]]

E：需要明确的是，这不会产生随机输出，因为您的输入没有随机性。但我认为它模仿了你的代码试图做的事情。

于 2013-09-22T14:35:41.820 回答
0

虽然这是一个老问题，但我最终很久以前就找到了解决方案。接下来是脚本，以便任何人都可以使用它。作为种子，您应该传递一个动态或随机值，您可以将其作为属性传递给着色器。

float getNoise(vec2 seed)
{
    vec2 theta_factor_a = vec2(0.9898, 0.233);
    vec2 theta_factor_b = vec2(12.0, 78.0);
    
    float theta_a = dot(seed.xy, theta_factor_a);
    float theta_b = dot(seed.xy, theta_factor_b);
    float theta_c = dot(seed.yx, theta_factor_a);
    float theta_d = dot(seed.yx, theta_factor_b);
    
    float value = cos(theta_a) * sin(theta_b) + sin(theta_c) * cos(theta_d);
    float temp = mod(197.0 * value, 1.0) + value;
    float part_a = mod(220.0 * temp, 1.0) + temp;
    float part_b = value * 0.5453;
    float part_c = cos(theta_a + theta_b) * 0.43758;

    return fract(part_a + part_b + part_c);
}
于 2020-07-17T08:30:26.917 回答