1

请帮助我了解如何获取自定义类实例以访问时间轴上定义的变量。

我没有使用文档类，因为这个程序将是一个多阶段的记忆实验，所以使用时间线最适合我。（FWIW，我也没有使用 xml；只是尽量保持简单。）现在我刚刚制作了一个简单的单帧 fla，我正在尝试在其上进行词汇测试。我制作了一个名为 VocabQ 的自定义类，它又包含一个名为 VocabButton 的自定义类的 4 个实例。现在，单击其中一个按钮只会跟踪按钮标签。但我希望它也更新在时间线上声明的字符串变量 CurrentResponse 的值。如果我只是尝试从 VocabButton 类中引用 CurrentResponse，则会收到错误“1120：未定义属性的访问...”。

根据我在互联网上找到的讨论，我尝试了各种方法，但还没有成功，只会变得更加困惑。请帮忙！（如果存在简单的解决方案，将不胜感激！）请参见下面的代码。谢谢你，~杰森

时间线中的代码：

import VocabQ;
import flash.display.*;
stop();

var CurrentResponse:String="NA";

var VocabQuestion = new VocabQ("VocabWord",["answerA","answerB","answerC","answerD"]);
addChild(VocabQuestion);

VocabQ.as 代码：

package
{
    import flash.display.*;
    import flash.events.*;
    import flash.net.*;
    import flash.text.*;
    import VocabButton;

    public class VocabQ extends MovieClip{
        private var _VocabWordText:String;
        private var _VocabWord:TextField;
        private var _ResponseOptions:Array;

        public function VocabQ(VocabWordText:String,ResponseOptions:Array){         
        _VocabWordText=VocabWordText;
        _ResponseOptions=ResponseOptions;
        build();
        }

        private function build():void{          
            _VocabWord = new TextField();
            _VocabWord.text=_VocabWordText;
            _VocabWord.x=25;
            _VocabWord.y=25;
            _VocabWord.textColor = 0x000000;
            addChild(_VocabWord);

            for (var i:int; i < _ResponseOptions.length; i++){
                var _VocabButton:VocabButton = new VocabButton(_ResponseOptions[i]);
                _VocabButton.x = 25 + (_VocabWord.width) + 10 + ((_VocabButton.width + 2) * i);
                _VocabButton.y = 25;
                addChild(_VocabButton);
                }
            }       
    }
}

VocabButton.as 代码：

package 
{
    import flash.display.*;
    import flash.text.*;
    import flash.events.*;

    public class VocabButton extends MovieClip{
        private var _btnLabel:TextField;

        public function VocabButton(labl:String){

            _btnLabel = new TextField();       
            _btnLabel.textColor = 0x000000;
            _btnLabel.text = labl;
            _btnLabel.border=true;
            _btnLabel.borderColor=0x000000;
            _btnLabel.background=true;
            _btnLabel.backgroundColor= 0xDAF4F0;
            _btnLabel.mouseEnabled = false;
            _btnLabel.selectable=false;
            _btnLabel.width=100;
            _btnLabel.height=18;        
            buttonMode=true;
            useHandCursor=true;
            addEventListener(MouseEvent.CLICK,onClick,false,0,true);

            addChild(_btnLabel);
        }

        private function onClick(evt:MouseEvent):void{
        trace(_btnLabel.text);  
        //CurrentResponse=_btnLabel.text;  //causes error 1120: Access of undefined property...
        }
    }
}
4

1 回答 1

0

这应该有效：

private function onClick(evt:MouseEvent):void {
    trace(_btnLabel.text);  
    evt.currentTarget.root.CurrentResponse=_btnLabel.text;
}

请参阅此处的讨论：http ://www.actionscript.org/forums/showthread.php3?t=161188

就个人而言，与其尝试像这样访问时间线，我更愿意VocabQuestion在时间线上为您添加一个点击侦听器并允许事件冒泡，或者，如果您的班级中有许多按钮，则扩展EventDispatcher并创建一些自定义事件，这些事件同样可以在您的时间轴上处理，但对于一个简单的测试，访问该root属性就足够了。

于 2012-11-23T19:29:20.070 回答