14

我想知道是否有人拥有完整、有效且有效的代码来在 glsl 中进行双三次纹理过滤。有这个：

http://www.codeproject.com/Articles/236394/Bi-Cubic-and-Bi-Linear-Interpolation-with-GLSL 或 https://github.com/visionworkbench/visionworkbench/blob/master/src/vw/ GPU/着色器/Interp/interpolation-bicubic.glsl

但两者都进行了 16 次纹理读取，其中只需要 4 次：

https://groups.google.com/forum/#!topic/comp.graphics.api.opengl/kqrujgJfTxo

然而，上面的方法使用了一个我不知道它应该做什么的缺失的“cubic()”函数，并且还采用了一个无法解释的“texscale”参数。

还有 NVidia 版本：

https://developer.nvidia.com/gpugems/gpugems2/part-iii-high-quality-rendering/chapter-20-fast-third-order-texture-filtering

但我相信这使用了 CUDA，这是 NVidia 显卡特有的。我需要gsl。

我可能可以将 nvidia 版本移植到 glsl，但我想我会先询问是否有人已经拥有完整的、工作的 glsl 双三次着色器。

4

8 回答 8

19

我发现这个实现可以用作 texture() 的替代品（来自http://www.java-gaming.org/index.php?topic=35123.0（一个错字已修复））：

// from http://www.java-gaming.org/index.php?topic=35123.0
vec4 cubic(float v){
    vec4 n = vec4(1.0, 2.0, 3.0, 4.0) - v;
    vec4 s = n * n * n;
    float x = s.x;
    float y = s.y - 4.0 * s.x;
    float z = s.z - 4.0 * s.y + 6.0 * s.x;
    float w = 6.0 - x - y - z;
    return vec4(x, y, z, w) * (1.0/6.0);
}

vec4 textureBicubic(sampler2D sampler, vec2 texCoords){

   vec2 texSize = textureSize(sampler, 0);
   vec2 invTexSize = 1.0 / texSize;

   texCoords = texCoords * texSize - 0.5;


    vec2 fxy = fract(texCoords);
    texCoords -= fxy;

    vec4 xcubic = cubic(fxy.x);
    vec4 ycubic = cubic(fxy.y);

    vec4 c = texCoords.xxyy + vec2 (-0.5, +1.5).xyxy;

    vec4 s = vec4(xcubic.xz + xcubic.yw, ycubic.xz + ycubic.yw);
    vec4 offset = c + vec4 (xcubic.yw, ycubic.yw) / s;

    offset *= invTexSize.xxyy;

    vec4 sample0 = texture(sampler, offset.xz);
    vec4 sample1 = texture(sampler, offset.yz);
    vec4 sample2 = texture(sampler, offset.xw);
    vec4 sample3 = texture(sampler, offset.yw);

    float sx = s.x / (s.x + s.y);
    float sy = s.z / (s.z + s.w);

    return mix(
       mix(sample3, sample2, sx), mix(sample1, sample0, sx)
    , sy);
}

示例：最近的、双线性的、双三次的：

在此处输入图像描述

该图像的 ImageData 是

{{{0.698039, 0.996078, 0.262745}, {0., 0.266667, 1.}, {0.00392157, 
   0.25098, 0.996078}, {1., 0.65098, 0.}}, {{0.996078, 0.823529, 
   0.}, {0.498039, 0., 0.00392157}, {0.831373, 0.00392157, 
   0.00392157}, {0.956863, 0.972549, 0.00784314}}, {{0.909804, 
   0.00784314, 0.}, {0.87451, 0.996078, 0.0862745}, {0.196078, 
   0.992157, 0.760784}, {0.00392157, 0.00392157, 0.498039}}, {{1., 
   0.878431, 0.}, {0.588235, 0.00392157, 0.00392157}, {0.00392157, 
   0.0666667, 0.996078}, {0.996078, 0.517647, 0.}}}

我试图重现这一点（许多其他插值技术）

在此处输入图像描述

但他们有夹住填充，而我有重复（包装）边界。因此并不完全相同。

似乎这种双三次业务不是适当的插值，即它不会在定义数据的点处采用原始值。

于 2017-02-11T18:55:09.223 回答
10

我决定花一点时间挖掘我以前的 Perforce 活动，并找到了缺失的 cube() 函数；请享用！:)

vec4 cubic(float v)
{
    vec4 n = vec4(1.0, 2.0, 3.0, 4.0) - v;
    vec4 s = n * n * n;
    float x = s.x;
    float y = s.y - 4.0 * s.x;
    float z = s.z - 4.0 * s.y + 6.0 * s.x;
    float w = 6.0 - x - y - z;
    return vec4(x, y, z, w);
}
于 2014-05-21T13:32:36.647 回答
7

JAre 的答案cubic()中缺少的函数可能如下所示：

vec4 cubic(float x)
{
    float x2 = x * x;
    float x3 = x2 * x;
    vec4 w;
    w.x =   -x3 + 3*x2 - 3*x + 1;
    w.y =  3*x3 - 6*x2       + 4;
    w.z = -3*x3 + 3*x2 + 3*x + 1;
    w.w =  x3;
    return w / 6.f;
}

它返回三次 B 样条的四个权重。

这一切都在NVidia Gems中进行了解释。

于 2013-02-09T19:47:02.277 回答
6

哇。我在 2011 年初提出了上面的代码（我无法评论声誉 < 50）。我试图解决的问题与旧的 IBM T42 （抱歉，确切的型号让我忘记了）笔记本电脑和它是 ATI 图形堆栈。我在 NV 卡上开发了代码，最初我使用了 16 个纹理提取。对于我的目的来说，这有点慢但足够快。当有人报告它在他的笔记本电脑上不起作用时，很明显他们不支持每个片段的足够纹理提取。我不得不设计一个变通方法，我能想到的最好的办法就是使用可以工作的纹理提取数量来做到这一点。

我是这样想的：好的，所以如果我用线性滤波器处理每个四边形（2x2），剩下的问题是行和列可以共享权重吗？这是我着手编写代码时唯一想到的问题。当然可以共享它们；每列和每行的权重相同；完美的！

现在我有四个样品。剩下的问题是如何正确组合样本。这是要克服的最大障碍。用铅笔和纸花了大约 10 分钟。我用颤抖的手输入了代码，它工作了，很好。然后我将二进制文件上传给承诺在他的 T42 上检查它的人（？），他报告说它有效。结束。:)

我可以保证方程检查出来并给出数学上相同的结果来单独计算样本。仅供参考：使用 CPU，分别进行水平和垂直扫描会更快。使用 GPU 多次传递并不是一个好主意，尤其是在典型用例中它可能无论如何都不可行时。

深思熟虑：可以对cubic() 函数使用纹理查找。哪个更快取决于 GPU，但一般来说，ALU 端的采样器很轻，只是做算术会平衡事情。YMMV。

于 2014-05-21T10:34:26.683 回答
4

（编辑）

三次样条

  • Texscale 是采样窗口大小系数。您可以从 1.0 值开始。
vec4 filter(sampler2D texture, vec2 texcoord, vec2 texscale)
{
    float fx = fract(texcoord.x);
    float fy = fract(texcoord.y);
    texcoord.x -= fx;
    texcoord.y -= fy;

    vec4 xcubic = cubic(fx);
    vec4 ycubic = cubic(fy);

    vec4 c = vec4(texcoord.x - 0.5, texcoord.x + 1.5, texcoord.y -
0.5, texcoord.y + 1.5);
    vec4 s = vec4(xcubic.x + xcubic.y, xcubic.z + xcubic.w, ycubic.x +
ycubic.y, ycubic.z + ycubic.w);
    vec4 offset = c + vec4(xcubic.y, xcubic.w, ycubic.y, ycubic.w) /
s;

    vec4 sample0 = texture2D(texture, vec2(offset.x, offset.z) *
texscale);
    vec4 sample1 = texture2D(texture, vec2(offset.y, offset.z) *
texscale);
    vec4 sample2 = texture2D(texture, vec2(offset.x, offset.w) *
texscale);
    vec4 sample3 = texture2D(texture, vec2(offset.y, offset.w) *
texscale);

    float sx = s.x / (s.x + s.y);
    float sy = s.z / (s.z + s.w);

    return mix(
        mix(sample3, sample2, sx),
        mix(sample1, sample0, sx), sy);
}

来源

于 2012-11-21T21:37:56.937 回答
2

对于任何对 GLSL 代码进行三次三次插值感兴趣的人，可以在以下示例/glCubicRayCast 文件夹中找到使用三次插值的光线投射代码： http ://www.dannyruijters.nl/cubicinterpolation/CI.zip

编辑：三次插值代码现在在 github 上可用：CUDA版本和WebGL版本，以及GLSL示例。

于 2013-08-05T09:21:08.677 回答
1

我已经使用 @Maf 的三次样条配方一年多了，如果三次 B 样条满足您的需求，我推荐它。

但我最近意识到，对于我的特定应用，强度在采样点处完全匹配非常重要。所以我改用了 Catmull-Rom 样条，它使用了一个稍微不同的配方，如下所示：

// Catmull-Rom spline actually passes through control points
vec4 cubic(float x) // cubic_catmullrom(float x)
{
    const float s = 0.5; // potentially adjustable parameter
    float x2 = x * x;
    float x3 = x2 * x;
    vec4 w;
    w.x =    -s*x3 +     2*s*x2 - s*x + 0;
    w.y = (2-s)*x3 +   (s-3)*x2       + 1;
    w.z = (s-2)*x3 + (3-2*s)*x2 + s*x + 0;
    w.w =     s*x3 -       s*x2       + 0;
    return w;
}

我在以下的讲义中找到了这些系数，以及其他一些三次样条曲线的系数： http ://www.cs.cmu.edu/afs/cs/academic/class/15462-s10/www/lec -幻灯片/lec06.pdf

于 2015-09-18T18:35:55.513 回答
0

我认为 Catmull 版本可以通过 4 次纹理查找来完成，方法是 (a) 将输入纹理排列为像棋盘一样，将备用槽保存为正数和负数，以及 (b) 对 textureBicubic 进行相关修改。这将取决于贡献/权重 wx/ww 始终为负，而贡献 wy/wz 始终为正。我没有仔细检查这是否属实，或者修改后的 textureBicubic 的外观。

...我已经验证 w 贡献确实满足 +ve -ve 规则。

于 2018-12-21T10:00:39.250 回答